Funkcije u ekonomiji

(%i1) load(draw)$

1 Zadatak

a) dio

funkcija potražnje

(%i2) solve([350*a+b=200,a=20/(-10)],[a,b]);
(%o2) [[a=-2,b=900]]
(%i3) f(p):=-2*p+900;
(%o3) f(p):=900-2*p

funkcija prihoda

(%i4) g(p):=expand(p*f(p));
(%o4) g(p):=expand(p*f(p))
(%i5) g(p);
(%o5) 900*p-2*p^2

grafovi

(%i6) wxplot2d(f(p), [p,0,600],grid2d)$
(%t6)
(Graphics)
(%i7) wxplot2d(g(p), [p,0,500],grid2d)$
(%t7)
(Graphics)

b) dio

(%i8) der:diff(g(p),p);
(der) 900-4*p
(%i9) solve(der=0,p);
(%o9) [p=225]

druga derivacija u p=225 je manja od nule pa se radi o maksimumu

(%i10) der2:diff(g(p),p,2);
(der2) -4
(%i11) subst(225,p,der2);
(%o11) -4

maksimalni prihod

(%i12) g(225);
(%o12) 101250

smanjenje cijene za 125 eura da bi se ostvario maksimalni prihod

(%i13) 350-225;
(%o13) 125

ODGOVOR: Maksimalni prihod se ostvaruje po cijeni od 225 eura i on iznosi 101250 eura.
Kako trgovina prodaje glazbene linije po cijeni od 350 eura, da bi ostvarila maksimalni
prihod, mora cijenu glazbene linije smanjiti za 125 eura.

obje funkcije zajedno s istaknutim maksimalnim prihodom i početnim prihodom

(%i14) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,600],ytics=[-20000,10000,110000],line_width=3,color=green,
key="potražnja",explicit(f(p),p,0,600), color=blue, key="prihod", explicit(g(p),p,0,500),color=red,point_type=filled_circle,
point_size=1.5,key="maksimalni prihod",points([[225,101250]]),key="",line_type=dots,line_width=2,
parametric(225,t,t,-20000,101250),parametric(t,101250,t,0,225),
key="početni prihod",color=brown,points([[350,70000]]),key="",
parametric(350,t,t,-20000,70000),parametric(t,70000,t,0,350),
yrange=[-20000,105000]),wxplot_size=[950,600];
(%t14)
(Graphics)
(%o14)
(%i15) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,600],ytics=[-20000,10000,110000],line_width=3,color=green,
key="potražnja",explicit(f(p),p,0,600), color=blue, key="prihod", explicit(g(p),p,0,500),color=red,point_type=filled_circle,
point_size=1.5,key="maksimalni prihod",points([[225,101250]]),key="",line_type=dots,
parametric(225,t,t,-20000,101250),parametric(t,101250,t,0,225),
key="početni prihod",color=brown,points([[350,70000]]),key="",
parametric(350,t,t,-20000,70000),parametric(t,70000,t,0,350),
yrange=[-20000,105000]);
(%o15) [gr2d(explicit,explicit,points,parametric,parametric,points,parametric,parametric)]

2 Zadatak

(%i17) q1(p):=-3*p^2+14*p-10;
q2(p):=p+2;
(%o16) q1(p):=-10+14*p-3*p^2
(%o17) q2(p):=2+p

a) dio

nultočke funkcije q1

(%i18) solve(q1(p)=0,p);
(%o18) [p=-(sqrt(19)-7)/3,p=(7+sqrt(19))/3]
(%i19) float(%);
(%o19) [p=0.8803670188197753,p=3.786299647846891]

tjeme parabole q1

(%i20) der1:diff(q1(p),p);
(der1) 14-6*p
(%i21) solve(der1=0,p);
(%o21) [p=7/3]
(%i22) q1(7/3);
(%o22) 19/3

grafovi funkcija

(%i23) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,6],ytics=[-4,1,8],line_width=3,color=red,
key="potražnja",explicit(q1(p),p,0,6), color=blue, key="ponuda", explicit(q2(p),p,0,5.2),
yrange=[-4,8]),wxplot_size=[800,600];
(%t23)
(Graphics)
(%o23)
(%i24) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,6],ytics=[-4,1,8],line_width=3,color=red,
key="potražnja",explicit(q1(p),p,0,6), color=blue, key="ponuda", explicit(q2(p),p,0,5.2),
yrange=[-4,8]);
(%o24) [gr2d(explicit,explicit)]

b) dio

cijena ekvilibrija je cijena za koju su ponuda i potražnja jednake

(%i25) solve(q1(p)=q2(p),p);
(%o25) [p=3,p=4/3]

ponuda i potražnja u cijenama ekvilibrija (uočite da su jednake)

(%i26) [q1(3),q2(3)];
(%o26) [5,5]
(%i27) [q1(4/3),q2(4/3)];
(%o27) [10/3,10/3]

ekvilibriji istaknuti na slici

(%i28) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,6],ytics=[-4,1,8],line_width=3,color=red,
key="potražnja",explicit(q1(p),p,0,6), color=blue, key="ponuda", explicit(q2(p),p,0,5.2),
color="#23ab0f",key="tocke ekvilibrija",point_type=filled_circle,point_size=2,
points([[3,5],[4/3,10/3]]),
yrange=[-4,8]),wxplot_size=[800,600];
(%t28)
(Graphics)
(%o28)
(%i29) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,6],ytics=[-4,1,8],line_width=3,color=red,
key="potražnja",explicit(q1(p),p,0,6), color=blue, key="ponuda", explicit(q2(p),p,0,5.2),
color="#23ab0f",key="tocke ekvilibrija",point_type=filled_circle,point_size=2,
points([[3,5],[4/3,10/3]]),
yrange=[-4,8]);
(%o29) [gr2d(explicit,explicit,points)]

c) dio

elastičnost potražnje u p=3

(%i30) der1:diff(q1(p),p);
(der1) 14-6*p
(%i31) q1(3);
(%o31) 5
(%i32) subst(3,p,der1);
(%o32) -4
(%i33) 3/q1(3)*subst(3,p,der1),numer;
(%o33) -2.4

INTERPRETACIJA: Ako na razini cijene p=3 cijenu povećamo za 1%, potražnja će se smanjiti za 2.4%.

elastičnost ponude u p=3

(%i34) der2:diff(q2(p),p);
(der2) 1
(%i35) q2(3);
(%o35) 5
(%i36) subst(3,p,der2);
(%o36) 1
(%i37) 3/q2(3)*subst(3,p,der2),numer;
(%o37) 0.6

INTERPRETACIJA: Ako na razini cijene p=3 cijenu povećamo za 1%, ponuda će se povećati za 0.6%.

3 Zadatak

(%i38) T(x):=0.001*x^3+10*x+2000;
(%o38) T(x):=2000+10*x+0.001*x^3

a) dio

prosječni troškovi

(%i39) Tp(x):=expand(T(x)/x);
(%o39) Tp(x):=expand(T(x)/x)
(%i40) Tp(x);
(%o40) 0.001*x^2+2000/x+10

granični troškovi

(%i41) Tg(x):=subst(x,y,diff(T(y),y));
(%o41) Tg(x):=subst(x,y,'diff(T(y),y,1))
(%i42) Tg(x);
(%o42) 0.003*x^2+10

grafovi prosječnih i graničnih troškova

(%i43) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,200],ytics=[0,25,200],line_width=3,color=red,
key="prosječni troškovi",explicit(Tp(x),x,0,200), color=blue, key="granični troškovi", explicit(Tg(x),x,0,200),
yrange=[0,200]),wxplot_size=[700,500];
(%t43)
(Graphics)
(%o43)
(%i44) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,200],ytics=[0,25,200],line_width=3,color=red,
key="prosječni troškovi",explicit(Tp(x),x,0,200), color=blue, key="granični troškovi", explicit(Tg(x),x,0,200),
yrange=[0,200]);
(%o44) [gr2d(explicit,explicit)]

b) dio

(%i45) d:diff(Tp(x),x);
(d) 0.002*x-2000/x^2

samo je jedna realna stacionarna točka x=100

(%i46) solve(d=0,x);
rat: replaced 0.002 by 1/500 = 0.002
(%o46) [x=50*sqrt(3)*%i-50,x=-50*sqrt(3)*%i-50,x=100]

druga derivacija u x=100 je veća od nule pa se radi o minimumu

(%i47) d2:diff(Tp(x),x,2);
(d2) 4000/x^3+0.002
(%i48) subst(100,x,d2);
(%o48) 0.006

prosječni minimalni troškovi su jednaki graničnim troškovima za x=100

(%i49) [Tp(100),Tg(100)];
(%o49) [40.0,40.0]

ODGOVOR: Prosječni troškovi su minimalni za 100 proizvoda. U tom slučaju su granični troškovi jednaki minimalnim prosječnim troškovima.
Na grafu se prosječni i granični troškovi sijeku baš za x=100, tj. u točki (100,40).

(%i50) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,200],ytics=[0,20,200],line_width=3,color=red,
key="prosječni troškovi",explicit(Tp(x),x,0,200), color=blue, key="granični troškovi", explicit(Tg(x),x,0,200),
point_size=2,color="#23ab0f",point_type=filled_circle,key="Tp(100)=Tg(100)",points([[100,40]]),
yrange=[0,200]),wxplot_size=[700,500];
(%t50)
(Graphics)
(%o50)
(%i51) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,200],ytics=[0,20,200],line_width=3,color=red,
key="prosječni troškovi",explicit(Tp(x),x,0,200), color=blue, key="granični troškovi", explicit(Tg(x),x,0,200),
point_size=2,color="#23ab0f",point_type=filled_circle,key="Tp(100)=Tg(100)",points([[100,40]]),
yrange=[0,200]);
(%o51) [gr2d(explicit,explicit,points)]

4 Zadatak

(%i52) T(Q):=2009+1000*(Q-2)/(3*Q+4);
(%o52) T(Q):=(1000*(Q-2))/(4+3*Q)+2009

a) dio

(%i53) Tg(Q):=ratsimp(subst(Q,x,diff(T(x),x)))$
(%i54) Tg(Q);
(%o54) 10000/(9*Q^2+24*Q+16)
(%i55) Tg(9),numer;
rat: replaced 10.40582726326742 by 10000/961 = 10.40582726326743
(%o55) 10.40582726326743

ili ako vam je nejasna gornja definicija od Tg(Q), možete i jednostavnije postupiti

(%i56) dT:diff(T(Q),Q);
(dT) 1000/(3*Q+4)-(3000*(Q-2))/(4+3*Q)^2
(%i57) ratsimp(dT);
(%o57) 10000/(9*Q^2+24*Q+16)
(%i58) subst(9.0,Q,dT);
(%o58) 10.40582726326742

INTERPRETACIJA: Ako na razini proizvodnje Q=9 proizvodnju povećamo za 1 proizvod, troškovi će se povećati za 10.41 novčanih jedinica.

b) dio

(%i59) T(9.0);
(%o59) 2234.806451612903
(%i60) 9/T(9.0)*Tg(9.0);
rat: replaced 10.40582726326742 by 10000/961 = 10.40582726326743
(%o60) 0.04190628915618893

ili koristeći drugi način i varijablu dT

(%i61) 9/T(9.0)*subst(9.0,Q,dT);
(%o61) 0.04190628915618891

INTERPRETACIJA: Ako na razini proizvodnje Q=9 proizvodnju povećamo za 1%, troškovi će se povećati za 0.0419%.

5 Zadatak

(%i62) Tp(Q):=(Q+2)/(Q+1);
(%o62) Tp(Q):=(2+Q)/(1+Q)

a) dio

funkcija troškova

(%i63) T(Q):=Q*Tp(Q);
(%o63) T(Q):=Q*Tp(Q)
(%i64) T(Q);
(%o64) (Q*(2+Q))/(Q+1)

funkcija graničnih troškova

(%i65) diff(T(Q),Q);
(%o65) Q/(Q+1)+(2+Q)/(Q+1)-(Q*(2+Q))/(1+Q)^2
(%i66) ratsimp(%);
(%o66) (2+2*Q+Q^2)/(Q^2+2*Q+1)

možemo sve u jednom retku odjedanput napraviti

(%i67) ratsimp(diff(T(Q),Q));
(%o67) (2+2*Q+Q^2)/(Q^2+2*Q+1)

b) dio

(%i68) solve(Tp(Q)=1.05,Q);
rat: replaced -1.05 by -21/20 = -1.05
(%o68) [Q=19]
(%i69) T(19);
(%o69) 399/20
(%i70) T(19.0);
(%o70) 19.95

ODGOVOR: Prosječni troškovi su jednak 1.05 na razini proizvodnje od 19 proizvoda.
U tom slučaju su troškovi jednaki 19.95 novčanih jedinica.

6 Zadatak

definiramo svoju funkciju koja će nam odmah za zadane točke na izlazu dati obje normalne jednadžbe;
naravno, možemo zadatak rješavati korak po korak, ali od ovoga je višestruka korist - možemo tu istu funkciju i u drugim takvim zadacima koristiti da ne moramo ponovo sve pješice raditi

(%i71) linearni_model(cijena,kolicina,a,b):=block([jedn1,jedn2],
                                    jedn1:lsum(i,i,cijena)*a+length(cijena)*b=lsum(i,i,kolicina),
                                    jedn2:lsum(i,i,cijena^2)*a+lsum(i,i,cijena)*b=lsum(i,i,cijena*kolicina),
                                    [jedn1,jedn2])$
(%i72) jedn:linearni_model([200,150,120,100],[15,22,25,30],a,b);
(jedn) [4*b+570*a=92,570*b+86900*a=12300]
(%i73) solve(jedn,[a,b]);
(%o73) [[a=-162/1135,b=9838/227]]
(%i74) float(%);
(%o74) [[a=-0.1427312775330396,b=43.33920704845815]]

linearna funkcija koja najbolje aproksimira funkciju zadanu tablicom

(%i75) q(p):=-162/1135*p+9838/227;
(%o75) q(p):=9838/227+(-162*p)/1135

slika - pazite niti jedna točka iz tablice zapravo nije na dobivenom pravcu;
neke su točke jako blizu tog pravca pa se čini kao da su na njemu;
na primjer, q(150)=21.9295, što je jako blizu broju 22 iz tablice

(%i76) [q(200.0),q(150.0),q(120.0),q(100.0)];
(%o76) [14.79295154185021,21.9295154185022,26.21145374449339,29.06607929515418]
(%i77) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[0,2,50],line_width=2,color=blue,
key="linearni model",explicit(q(p),p,0,220), color=red, key="tablica", point_size=1,point_type=filled_circle,
points([[200,15],[150,22],[120,25],[100,30]]),yrange=[0,50]),wxplot_size=[900,600];
(%t77)
(Graphics)
(%o77)
(%i78) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[0,2,50],line_width=2,color=blue,
key="linearni model",explicit(q(p),p,0,220), color=red, key="tablica", point_size=1,point_type=filled_circle,
points([[200,15],[150,22],[120,25],[100,30]]),yrange=[0,50]);
(%o78) [gr2d(explicit,points)]

a) dio

dnevno se maksimalno traži oko 43 jakne

(%i79) q(0.0);
(%o79) 43.33920704845815

po cijeni od 110 kn traži se oko 28 jakni dnevno

(%i80) q(110.0);
(%o80) 27.63876651982379

35 jakni dnevno se tra\v{z}i po cijeni od 58 kn i 43 lipe

(%i81) solve(q(p)=35,p);
(%o81) [p=3155/54]
(%i82) float(%);
(%o82) [p=58.42592592592592]

slika s istaknutim točkama za p=110 i q=35-

(%i83) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[0,2,50],line_width=2,color=blue,
key="linearni model",explicit(q(p),p,0,220), color=red, key="tablica", point_size=1,point_type=filled_circle,
points([[200,15],[150,22],[120,25],[100,30]]),color="#23ab0f",key="q(110)=27.64",point_type=5,point_size=1.5,
points([[110,27.6387665]]),point_type=4,key="q(58.43)=35",points([[58.43,35]]),
line_type=dots,key="",line_width=2,parametric(110,t,t,0,27.64),parametric(t,27.64,t,0,110),
parametric(58.42,t,t,0,35),parametric(t,35,t,0,60),
yrange=[0,50]),wxplot_size=[1100,700];
(%t83)
(Graphics)
(%o83)
(%i84) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[0,2,50],line_width=2,color=blue,
key="linearni model",explicit(q(p),p,0,220), color=red, key="tablica", point_size=1,point_type=filled_circle,
points([[200,15],[150,22],[120,25],[100,30]]),color="#23ab0f",key="q(110)=27.64",point_type=5,point_size=1.5,
points([[110,27.6387665]]),point_type=4,key="q(58.43)=35",points([[58.43,35]]),
line_type=dots,key="",line_width=3,parametric(110,t,t,0,27.64),parametric(t,27.64,t,0,110),
parametric(58.43,t,t,0,35),parametric(t,35,t,0,58.43),
yrange=[0,50]);
(%o84) [gr2d(explicit,points,points,points,parametric,parametric,parametric,parametric)]

b) dio

(%i85) solve(2/dp=-162/1135,dp);
(%o85) [dp=-1135/81]
(%i86) float(%);
(%o86) [dp=-14.01234567901234]

ODGOVOR: Da bi se prodale dvije jakne više dnevno, cijenu treba smanjiti za 14 kuna i 1 lipu.
Nije uopće bitno po kojoj cijeni trenutno prodajemo jakne jer se radi o linearnoj funkciji.

c) dio

(%i87) diff(q(p),p);
(%o87) -162/1135
(%i88) 110/q(110)*(-162)/1135;
(%o88) -1782/3137
(%i89) float(%);
(%o89) -0.5680586547656997

ODGOVOR: Ako se cijena jakne na razini p=110 poveća za 1%, potražnja za jaknama se smanji za 0.568%.
Kako je elastičnost u točki p=110 po apsolutnoj vrijednosti strogo manja od 1, povećanjem cijene na
razini p=110 za 1%, prihod će se povećati.

7 Zadatak

(%i91) T(x):=0.00007*x^3-0.01*x^2+1.26*x+84;
p(x):=3.5-0.01*x;
(%o90) T(x):=84+1.26*x-0.01*x^2+7.0*10^-5*x^3
(%o91) p(x):=3.5-0.01*x

a) dio

funkcija prihoda

(%i92) P(x):=x*p(x);
(%o92) P(x):=x*p(x)
(%i93) P(x);
(%o93) (3.5-0.01*x)*x
(%i94) expand(P(x));
(%o94) 3.5*x-0.01*x^2

dobit = prihod - troškovi

(%i95) D(x):=P(x)-T(x);
(%o95) D(x):=P(x)-T(x)
(%i96) D(x);
(%o96) -7.0*10^-5*x^3+0.01*x^2+(3.5-0.01*x)*x-1.26*x-84
(%i97) expand(D(x));
(%o97) -7.0*10^-5*x^3+2.24*x-84.0

b) dio

dobit za 40 plakata

(%i98) D(40);
(%o98) 1.120000000000004

dobit za 150 plakata

(%i99) D(150);
(%o99) 15.75

c) dio

(%i100) der:diff(D(x),x);
(der) 2.24-2.099999999999999*10^-4*x^2
(%i101) solve(der=0,x);
rat: replaced 2.24 by 56/25 = 2.24rat: replaced -2.099999999999999E-4 by -21/100000 = -2.1E-4<BR>
(%o101) [x=-(16*5^(3/2))/sqrt(3),x=(16*5^(3/2))/sqrt(3)]
(%i102) float(%);
(%o102) [x=-103.2795558988644,x=103.2795558988644]

broj plakata ne može biti negativan pa uzimamo u obzir samo pozitivnu vrijednost x=103.28;
kako je druga derivacija negativna u toj točki, tada se zaista tu ostvaruje maksimum;

(%i103) der2:diff(D(x),x,2);
(der2) -4.199999999999999*10^-4*x
(%i104) subst(103.28,x,der2);
(%o104) -0.04337759999999999
(%i105) D(103.28);
(%o105) 70.23080347136002

ODGOVOR: Maksimalna dnevna dobit se ostvaruje za otprilike oko 103 prodanih plakata i iznosi 70 kuna i 23 lipe.

(%i106) p(103.28);
(%o106) 2.4672

ODGOVOR: Da bi studentice ostvarile maksimalnu dnevnu dobit, moraju plakate prodavati po 2 kune i 47 lipa.

d) dio

(%i107) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[-50,10,100],line_width=2,color=blue,
key="Dobit",explicit(D(x),x,0,200), color=red, key="maksimalna dobit", point_size=1.5,point_type=filled_circle,
points([[103.28,70.23]]),line_type=dots,key="",line_width=2,parametric(103.28,t,t,0,70.23),parametric(t,70.23,t,0,103.28),
label(["103.28",103.28,-3],["70.23",5,73]),yrange=[-50,100]),wxplot_size=[1100,700];
(%t107)
(Graphics)
(%o107)
(%i108) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[-50,10,100],line_width=2,color=blue,
key="Dobit",explicit(D(x),x,0,200), color=red, key="maksimalna dobit", point_size=1.5,point_type=filled_circle,
points([[103.28,70.23]]),line_type=dots,key="",line_width=3,parametric(103.28,t,t,0,70.23),parametric(t,70.23,t,0,103.28),
label(["103.28",103.28,-3],["70.23",5,73]),yrange=[-50,100]);
(%o108) [gr2d(explicit,points,parametric,parametric,label)]

ODGOVOR: Gledajući sliku i rezultate iz b) dijela zadatka, možemo zaključiti da studentice dnevno moraju prodavati između 40 i 150 plakata kako ne bi imale dnevni gubitak. Naravno, najbolje je da je dnevni broj prodanih kalendara što bliže broju 103 (jer se u njegovoj blizini postiže maksimalna dnevna dobit).

Želimo li baš dati precizni rezultat do kraja, morali bismo pronaći nultočke funkcije D(x) (ili otprilike što je moguće točnije sa slike dati što bolju procjenu). Ručno nam ne bi bilo ugodno tražiti nultočke jer se radi o jednadžbi trećeg stupnja, ali pomoću maksime možemo i to bez problema obaviti. Pritom nas negativna nultočka ne zanima jer broj plakata ne može biti negativan broj.

(%i109) allroots(D(x));
(%o109) [x=39.41327600839169,x=155.8921810570802,x=-195.3054570654718]

PRECIZNIJI ODGOVOR: Studentice dnevno moraju prodati između 40 i 155 plakata, kako ne bi imale dnevnih gubitaka. Naravno, kada rješavate ručno zadatak bez ovog programa, tada je i onaj prethodni odgovor zadovoljavajući jer ionako nam je stalo da broj prodanih plakata bude što je moguće bliži broju 103.

CIJENA: cijena ovisi padajuće linearno o broju plakata x; iskoristimo li podatke iz b) dijela zadatka zaključujemo da cijena plakata mora biti otprilike između 2 kune i 3 kune 1 lipe kako bi studentice imale dnevnu pozitivnu dobit.

(%i110) [p(40),p(150)];
(%o110) [3.1,2.0]

CIJENA - precizniji interval ako iskoristimo pozitivne nultočke funkcije dobiti:
Cijena plakata mora biti između 1 kune 94 lipa i 3 kune i 11 lipa kako bi studentice imale dnevnu pozitivnu dobit.

(%i111) [p(39.413276),p(155.892181)];
(%o111) [3.10586724,1.94107819]

NAPOMENA: Dobiveni maksimum je samo lokalnog karaktera za funkciju dobiti na njezinoj prirodnoj domeni. Ako pogledate donju sliku, vidjet ćete da ona postiže i veće vrijednosti od 70.23, samo se to događa na negativnom dijelu domene, a zbog prirode problema nas negativni dio domene ne zanima (jer broj plakata ne može biti negativan broj). No, na pozitivnom dijelu domene to je globalni maksimum.
Isto tako možete uočiti i lokalni minimum u točki x=-103.28, samo smo tu točku bili izbacili iz razmatranja jer broj plakata ne može biti negativan broj.

(%i112) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[-250,50,250],ytics=[-300,50,300],line_width=2,color=blue,
explicit(D(x),x,-250,250),yrange=[-300,300]),wxplot_size=[800,600];
(%t112)
(Graphics)
(%o112)
(%i113) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[-250,50,250],ytics=[-300,50,300],line_width=2,color=blue,
explicit(D(x),x,-250,250),yrange=[-300,300]);
(%o113) [gr2d(explicit)]

8 Zadatak

(%i114) q(p):=(2*p+1)*log(5*p)/log(4);
(%o114) q(p):=((1+2*p)*log(5*p))/log(4)

a) dio

derivacija funkcije ponude

(%i115) der:diff(q(p),p);
(der) (2*log(5*p))/log(4)+(1+2*p)/(log(4)*p)
(%i116) ratsimp(der);
(%o116) (1+2*p+2*p*log(5*p))/(log(4)*p)

vrijednosti ponude i njezine derivacije za p=10

(%i117) q(10),numer;
(%o117) 59.26048999263461
(%i118) subst(10,p,der),numer;
(%o118) 7.158685982708136

elastičnost ponude za p=10

(%i119) 10/q(10)*subst(10,p,der),numer;
(%o119) 1.208003171016283

INTERPRETACIJA: Ako na razini cijene p=10 cijenu povećamo za 1%, ponuda će se povećati za 1.208%.

b) dio

(%i120) q(18),numer;
(%o120) 120.0992822820989

ODGOVOR: Po cijeni od 18 novčanih jedinica nudi se oko 120 proizvoda.

(%i121) subst(18,p,der),numer;
(%o121) 7.974622999465554
(%i122) 18/q(18)*subst(18,p,der),numer;
(%o122) 1.195204594588783

ODGOVOR: Kako je za p=18 elastičnost po apsolutnoj vrijednosti veća od 1, ponuda je elastična za p=18.

9 Zadatak

(%i123) T(Q):=100*(3*Q+2007)/sqrt(3*Q+2007);
(%o123) T(Q):=(100*(2007+3*Q))/sqrt(2007+3*Q)

a) dio

funkcija graničnih troškova

(%i124) der:diff(T(Q),Q);
(der) 150/sqrt(3*Q+2007)

granični troškovi za Q=10

(%i125) subst(10.0,Q,der);
(%o125) 3.323500470219958

INTERPRETACIJA: Ako na razini proizvodnje Q=10 proizvodnju povećamo za 1 proizvod,
troškovi će se povećati za 3.32 novčane jedinice.

b) dio

(%i126) solve(T(Q)=5000,Q);
(%o126) [Q=493/3]
(%i127) float(%);
(%o127) [Q=164.3333333333333]

ODGOVOR: Da bi troškovi bili jednaki 5000, treba proizvesti oko 164 proizvoda.

10 Zadatak

(%i128) T(Q):=(Q^2+1000)/(Q+1);
(%o128) T(Q):=(1000+Q^2)/(1+Q)

a) dio

fiksni troškovi - troškovi za 0 proizvoda (kada još nema proizvodnje)

(%i129) T(0);
(%o129) 1000

varijabilni troškovi = troškovi - fiksni troškovi

(%i130) T(Q)-T(0);
(%o130) (1000+Q^2)/(Q+1)-1000
(%i131) ratsimp(%);
(%o131) (Q^2-1000*Q)/(Q+1)

b) dio

funkcija graničnih troškova

(%i132) der:diff(T(Q),Q);
(der) (2*Q)/(Q+1)-(1000+Q^2)/(1+Q)^2
(%i133) ratsimp(der);
(%o133) (-1000+2*Q+Q^2)/(Q^2+2*Q+1)

vrijednost troškova i graničnih troškova za Q=35

(%i134) T(35.0);
(%o134) 61.80555555555556
(%i135) subst(35.0,Q,der);
(%o135) 0.2276234567901236

elastičnost troškova za Q=35

(%i136) 35/T(35.0)*subst(35.0,Q,der);
(%o136) 0.1289013732833958

ODGOVOR: Ako na razini proizvodnje Q=35 proizvodnju povećamo za 1%, troškovi će se povećati za 0.1289%.

11 Zadatak

(%i137) Q(p):=2005+25*0.7^p;
(%o137) Q(p):=25*0.7^p+2005

a) dio

derivacija funkcije potražnje

(%i138) der:diff(Q(p),p);
(der) -8.91687359846831*0.7^p

vrijednost potražnje i njezine derivacije za p=4

(%i139) Q(4);
(%o139) 2011.0025
(%i140) subst(4,p,der);
(%o140) -2.140941350992241

elastičnost potražnje za p=4

(%i141) 4/Q(4)*subst(4,p,der);
(%o141) -0.004258455871620728

INTERPRETACIJA: Ako na razini cijene p=4 cijenu povećamo za 1%, potražnja će se smanjiti za 0.004%.

b) dio

Kako je elastičnost za p=4 po apsolutnoj vrijednosti manja od 1, ako se cijena na razini p=4
poveća za 1%, prihod će se povećati.

12 Zadatak

(%i142) q(p):=900-3*p;
(%o142) q(p):=900-3*p

a) dio

(%i143) 200/q(200)*(-3);
(%o143) -2

ODGOVOR: Kako je elastičnost ove funkcije za p=200 po apsolutnoj vrijednosti veća od 1,
zadana funkcija je elastična za p=200.

b) dio

ODGOVOR: Kako je elastičnost ove funkcije za p=200 po apsolutnoj vrijednosti veća od 1,
želimo li povećati prihod, moramo smanjiti cijenu.

c) dio

funkcija prihoda

(%i144) P(p):=p*q(p);
(%o144) P(p):=p*q(p)
(%i145) P(p);
(%o145) (900-3*p)*p

pomoću derivacije pronađemo ekstreme funkcije prihoda

(%i146) der:diff(P(p),p);
(der) 900-6*p
(%i147) solve(der=0,p);
(%o147) [p=150]

kako je druga derivacija za p=150 negativna, radi se o maksimumu

(%i148) der2:diff(P(p),p,2);
(der2) -6
(%i149) subst(150,p,der2);
(%o149) -6

maksimalni prihod

(%i150) P(150);
(%o150) 67500

ODGOVOR: Maksimalni prihod se ostvaruje uz cijenu od 150 kn i iznosi 67500 kn.

graf funkcije prihoda

(%i151) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="prihod",xtics=[0,10,300],ytics=[0,5000,80000],line_width=2,color=blue,
key="prihod",explicit(P(p),p,0,300), color=red, key="maksimalni prihod=67500", point_size=1.5,point_type=filled_circle,
points([[150,67500]]),yrange=[0,80000]),wxplot_size=[1200,600];
(%t151)
(Graphics)
(%o151)
(%i152) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="prihod",xtics=[0,10,300],ytics=[0,5000,80000],line_width=2,color=blue,
key="prihod",explicit(P(p),p,0,300), color=red, key="maksimalni prihod=67500", point_size=1.5,point_type=filled_circle,
points([[150,67500]]),yrange=[0,80000]);
(%o152) [gr2d(explicit,points)]

13 Zadatak

(%i153) q(p):=(4*p-2)^(1/4);
(%o153) q(p):=(4*p-2)^(1/4)

a) dio

derivacija funkcije ponude

(%i154) der:diff(q(p),p);
(der) 1/(4*p-2)^(3/4)

vrijednost funkcije ponude i njezine derivacije za p=20

(%i155) q(20.0);
(%o155) 2.971827866200841
(%i156) subst(20.0,p,der);
(%o156) 0.03810035725898514

elastičnost ponude za p=20

(%i157) 20/q(20.0)*subst(20.0,p,der);
(%o157) 0.2564102564102563

INTERPRETACIJA: Ako na razini cijene p=20 cijenu povećamo za 1%, ponuda će se povećati za 0.25641%.

b) dio

(%i158) solve(q(p)=10,p);
(%o158) [p=5001/2]
(%i159) float(%);
(%o159) [p=2500.5]

ODGOVOR: Po cijeni od 2500.5 novčanih jedinica ponudit će se točno 10 proizvoda.

c) dio

(%i160) elast:p/q(p)*der;
(elast) p/(4*p-2)
(%i161) solve(elast=0.26,p);
rat: replaced -0.26 by -13/50 = -0.26
(%o161) [p=13]

ODGOVOR: Elastičnost ponude je jednaka 0.26 na razini cijene p=13.

14 Zadatak

a) dio

(%i162) solve([10*a+b=27000,8*a+b=33000],[a,b]);
(%o162) [[a=-3000,b=57000]]
(%i163) q(p):=-3000*p+57000;
(%o163) q(p):=57000-3000*p

b) dio

funkcija prihoda

(%i164) P(p):=p*q(p);
(%o164) P(p):=p*q(p)
(%i165) expand(P(p));
(%o165) 57000*p-3000*p^2

pomoću derivacije pronađemo ekstreme funkcije prihoda

(%i166) der:diff(P(p),p);
(der) 57000-6000*p
(%i167) solve(der=0,p);
(%o167) [p=19/2]
(%i168) float(%);
(%o168) [p=9.5]

kako je druga derivacija za p=9.5 negativna, radi se o maksimumu

(%i169) der2:diff(P(p),p,2);
(der2) -6000
(%i170) subst(9.5,p,der2);
(%o170) -6000

maksimalni prihod

(%i171) P(9.5);
(%o171) 270750.0

ODGOVOR: Ulaznice treba prodavati po cijeni od 9.5 eura da bi se postigao maksimalni prihod od 270750 eura.

graf funkcije prihoda

(%i172) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="prihod",xtics=[0,1,20],ytics=[0,50000,280000],line_width=2,color=blue,
key="prihod",explicit(P(p),p,0,20), color=red, key="maksimalni prihod=270750", point_size=1.5,point_type=filled_circle,
points([[9.5,270750]]),yrange=[0,280000]),wxplot_size=[900,600];
(%t172)
(Graphics)
(%o172)
(%i173) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="prihod",xtics=[0,1,20],ytics=[0,50000,280000],line_width=2,color=blue,
key="prihod",explicit(P(p),p,0,20), color=red, key="maksimalni prihod=270750", point_size=1.5,point_type=filled_circle,
points([[9.5,270750]]),yrange=[0,280000]);
(%o173) [gr2d(explicit,points)]

15 Zadatak

(%i174) T(x):=3*x^2+x+48;
(%o174) T(x):=48+x+3*x^2

a) dio

prosječni troškovi

(%i175) Tp(x):=T(x)/x;
(%o175) Tp(x):=T(x)/x
(%i176) expand(Tp(x));
(%o176) 3*x+48/x+1

pomoću prve derivacije tražimo stacionarne točke funkcije Tp

(%i177) der:diff(Tp(x),x);
(der) (1+6*x)/x-(48+x+3*x^2)/x^2
(%i178) ratsimp(der);
(%o178) (3*x^2-48)/x^2

u obzir dolazi samo x=4 jer broj proizvoda ne može biti negativan broj

(%i179) solve(der=0,x);
(%o179) [x=-4,x=4]

druga derivacija u x=4 je pozitivna pa se radi o minimumu

(%i180) der2:diff(Tp(x),x,2);
(der2) (2*(48+x+3*x^2))/x^3-(2*(1+6*x))/x^2+6/x
(%i181) ratsimp(der2);
(%o181) 96/x^3
(%i182) subst(4,x,der2);
(%o182) 3/2

minimalni prosječni troškovi

(%i183) Tp(4);
(%o183) 25

ODGOVOR: Prosječni troškovi su minimalni za 4 proizvoda i iznose 25 novčanih jedinica.

b) dio

granični troškovi

(%i184) gr:diff(T(x),x);
(gr) 6*x+1

za koji x vrijedi prosječni troškovi = granični troškovi?

(%i185) solve(Tp(x)=gr,x);
(%o185) [x=-4,x=4]

ODGOVOR: Prosječni troškovi su jednaki graničnim troškovima za 4 proizvoda.

c) dio

prosječni i granični troškovi na jednoj slici

(%i186) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,10],ytics=[0,5,100],line_width=2,color=blue,
key="prosječni troškovi",explicit(Tp(x),x,0,10),color=red,key="granični troškovi",explicit(6*x+1,x,0,9.8),
key="min Tp=25",point_size=1.5,point_type=filled_circle,color=blue,
points([[4,25]]),yrange=[0,100]),wxplot_size=[800,600];
(%t186)
(Graphics)
(%o186)
(%i187) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,10],ytics=[0,5,100],line_width=2,color=blue,
key="prosječni troškovi",explicit(Tp(x),x,0,10),color=red,key="granični troškovi",explicit(6*x+1,x,0,9.8),
key="min Tp=25",point_size=1.5,point_type=filled_circle,color=blue,
points([[4,25]]),yrange=[0,100]);
(%o187) [gr2d(explicit,explicit,points)]

troškovi, prosječni troškovi i granični troškovi na jednoj slici

(%i188) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,10],ytics=[0,25,250],line_width=2,color=blue,
key="prosječni troškovi",explicit(Tp(x),x,0,10),color=red,key="granični troškovi",explicit(6*x+1,x,0,9.8),
color=brown,key="troškovi",explicit(T(x),x,0,9),
key="min Tp=25",point_size=1.5,point_type=filled_circle,color=blue,
points([[4,25]]),yrange=[0,250]),wxplot_size=[800,600];
(%t188)
(Graphics)
(%o188)
(%i189) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,10],ytics=[0,25,250],line_width=2,color=blue,
key="prosječni troškovi",explicit(Tp(x),x,0,10),color=red,key="granični troškovi",explicit(6*x+1,x,0,9.8),
color=brown,key="troškovi",explicit(T(x),x,0,9),
key="min Tp=25",point_size=1.5,point_type=filled_circle,color=blue,
points([[4,25]]),yrange=[0,250]);
(%o189) [gr2d(explicit,explicit,explicit,points)]

16 Zadatak

a) dio

(%i190) solve([a=-2/1,a*10+b=20],[a,b]);
(%o190) [[a=-2,b=40]]
(%i191) q(p):=-2*p+40;
(%o191) q(p):=40-2*p

b) dio

prihod

(%i192) P(p):=p*q(p);
(%o192) P(p):=p*q(p)
(%i193) expand(P(p));
(%o193) 40*p-2*p^2

dobit (profit) = prihod - troškovi

(%i194) D(p):=P(p)-6*q(p);
(%o194) D(p):=P(p)-6*q(p)
(%i195) D(p);
(%o195) (40-2*p)*p-6*(40-2*p)
(%i196) expand(D(p));
(%o196) -2*p^2+52*p-240

pomoću prve derivacije tražimo stacionarne točke funkcije dobiti

(%i197) der:diff(D(p),p);
(der) 52-4*p
(%i198) solve(der=0,p);
(%o198) [p=13]

druga derivacija za p=13 je manja od nule pa se radi o maksimumu

(%i199) der2:diff(D(p),p,2);
(der2) -4
(%i200) subst(13,p,der2);
(%o200) -4

maksimalni profit (dobit)

(%i201) D(13);
(%o201) 98

broj prodanih ogrlica kod maksimalnog profita

(%i202) q(13);
(%o202) 14

ODGOVOR: Student mora prodavati ogrlice po 13 eura ako želi ostvariti maksimalni profit
koji iznosi 98 eura. U tom slučaju će prodati 14 ogrlica.

17 Zadatak

(%i204) N(p):=1500/(p^2+100);
T(p):=2*N(p)+14;
(%o203) N(p):=1500/(100+p^2)
(%o204) T(p):=14+2*N(p)

profit = prihod - troškovi

(%i205) D(p):=p*N(p)-T(p);
(%o205) D(p):=p*N(p)-T(p)
(%i206) ratsimp(D(p));
(%o206) -(4400-1500*p+14*p^2)/(p^2+100)

pomoću prve derivacije tražimo stacionarne točke funkcije profita

(%i207) der:diff(D(p),p);
(der) 1500/(p^2+100)-(3000*p^2)/(100+p^2)^2+(6000*p)/(100+p^2)^2
(%i208) ratsimp(der);
(%o208) -(-150000-6000*p+1500*p^2)/(p^4+200*p^2+10000)

u obzir uzimamo samo pozitivno rješenje p=12.2

(%i209) solve(der=0,p);
(%o209) [p=2-2*sqrt(26),p=2*sqrt(26)+2]
(%i210) float(%);
(%o210) [p=-8.198039027185569,p=12.19803902718556]

druga derivacija za p=12.2 je negativna pa se radi o maksimumu

(%i211) der2:diff(D(p),p,2);
(der2) -(9000*p)/(100+p^2)^2+6000/(100+p^2)^2+(12000*p^3)/(100+p^2)^3-(24000*p^2)/(100+p^2)^3
(%i212) ratsimp(der2);
(%o212) (600000-900000*p-18000*p^2+3000*p^3)/(p^6+300*p^4+30000*p^2+1000000)
(%i213) subst(12.2,p,der2);
(%o213) -0.4939852825644972

maksimalni profit

(%i214) D(12.2);
(%o214) 47.48529175373735

ODGOVOR: Maksimalni profit iznosi 47.49 novčanih jedinica i ostvaruje se uz cijenu od 12.2 novčane jedinice.

graf funkcije profita na segmentu [3,100]

(%i215) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,5,100],ytics=[0,5,100],line_width=2,color=blue,
key="profit",explicit(D(p),p,0,100),color=red,key="maksimalni profit",point_size=1.5,point_type=filled_circle,
points([[12.198,47.485]]),key="",line_type=dots,line_width=2, parametric(12.198,t,t,0,47.485),parametric(t,47.485,t,0,12.198),
label(["12.2",14.5,2],["47.49",3,48.5]),yrange=[0,60]),wxplot_size=[1000,700];
(%t215)
(Graphics)
(%o215)
(%i216) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,5,100],ytics=[0,5,100],line_width=2,color=blue,
key="profit",explicit(D(p),p,0,100),color=red,key="maksimalni profit",point_size=1.5,point_type=filled_circle,
points([[12.198,47.485]]),key="",line_type=dots,parametric(12.198,t,t,0,47.485),parametric(t,47.485,t,0,12.198),
label(["12.2",13.5,2],["47.49",3,48.5]),yrange=[0,60]);
(%o216) [gr2d(explicit,points,parametric,parametric,label)]

graf funkcije profita na [-500,500]. Uočavamo da ima i minimum koji se postiže na negativnom dijelu domene (to je ona točka p=-8.2 koju smo gore zbog prirode problema izbacili iz razmatranja), a ima i horizontalnu asimptotu y=-14

(%i217) limit(D(p),p,inf);
(%o217) -14
(%i218) limit(D(p),p,minf);
(%o218) -14
(%i219) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[-500,50,500],ytics=[-120,10,60],line_width=2,color=red,
key="profit",explicit(D(p),p,-500,500),color=blue,line_type=dots,line_width=2,key="horizontalna asimptota: y=-14",
parametric(t,-14,t,-500,500),yrange=[-120,60]),wxplot_size=[1200,700];
(%t219)
(Graphics)
(%o219)
(%i220) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[-500,50,500],ytics=[-120,10,60],line_width=2,color=red,
key="profit",explicit(D(p),p,-500,500),color=blue,line_type=dots,line_width=3,key="horizontalna asimptota: y=-14",
parametric(t,-14,t,-500,500),yrange=[-120,60]);
(%o220) [gr2d(explicit,parametric)]
Created with wxMaxima.