# Funkcije u ekonomiji

load(draw)$

## Zadatak

a) dio

funkcija potražnje

solve([350*a+b=200,a=20/(-10)],[a,b]);

f(p):=-2*p+900;

funkcija prihoda

g(p):=expand(p*f(p));

g(p);

grafovi

wxplot2d(f(p), [p,0,600],grid2d)$

wxplot2d(g(p), [p,0,500],grid2d)$

b) dio

der:diff(g(p),p);

solve(der=0,p);

druga derivacija u p=225 je manja od nule pa se radi o maksimumu

der2:diff(g(p),p,2);

subst(225,p,der2);

maksimalni prihod

g(225);

smanjenje cijene za 125 eura da bi se ostvario maksimalni prihod

350-225;

ODGOVOR: Maksimalni prihod se ostvaruje po cijeni od 225 eura i on iznosi 101250 eura.
Kako trgovina prodaje glazbene linije po cijeni od 350 eura, da bi ostvarila maksimalni 
prihod, mora cijenu glazbene linije smanjiti za 125 eura.

obje funkcije zajedno s istaknutim maksimalnim prihodom i početnim prihodom

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,600],ytics=[-20000,10000,110000],line_width=3,color=green,
key="potražnja",explicit(f(p),p,0,600), color=blue, key="prihod", explicit(g(p),p,0,500),color=red,point_type=filled_circle,
point_size=1.5,key="maksimalni prihod",points([[225,101250]]),key="",line_type=dots,line_width=2,
parametric(225,t,t,-20000,101250),parametric(t,101250,t,0,225),
key="početni prihod",color=brown,points([[350,70000]]),key="",
parametric(350,t,t,-20000,70000),parametric(t,70000,t,0,350),
yrange=[-20000,105000]),wxplot_size=[950,600];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,600],ytics=[-20000,10000,110000],line_width=3,color=green,
key="potražnja",explicit(f(p),p,0,600), color=blue, key="prihod", explicit(g(p),p,0,500),color=red,point_type=filled_circle,
point_size=1.5,key="maksimalni prihod",points([[225,101250]]),key="",line_type=dots,
parametric(225,t,t,-20000,101250),parametric(t,101250,t,0,225),
key="početni prihod",color=brown,points([[350,70000]]),key="",
parametric(350,t,t,-20000,70000),parametric(t,70000,t,0,350),
yrange=[-20000,105000]);

## Zadatak

q1(p):=-3*p^2+14*p-10;
q2(p):=p+2;

a) dio

nultočke funkcije q1

solve(q1(p)=0,p);

float(%);

tjeme parabole q1

der1:diff(q1(p),p);

solve(der1=0,p);

q1(7/3);

grafovi funkcija

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,6],ytics=[-4,1,8],line_width=3,color=red,
key="potražnja",explicit(q1(p),p,0,6), color=blue, key="ponuda", explicit(q2(p),p,0,5.2),
yrange=[-4,8]),wxplot_size=[800,600];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,6],ytics=[-4,1,8],line_width=3,color=red,
key="potražnja",explicit(q1(p),p,0,6), color=blue, key="ponuda", explicit(q2(p),p,0,5.2),
yrange=[-4,8]);

b) dio

cijena ekvilibrija je cijena za koju su ponuda i potražnja jednake

solve(q1(p)=q2(p),p);

ponuda i potražnja u cijenama ekvilibrija (uočite da su jednake)

[q1(3),q2(3)];

[q1(4/3),q2(4/3)];

ekvilibriji istaknuti na slici

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,6],ytics=[-4,1,8],line_width=3,color=red,
key="potražnja",explicit(q1(p),p,0,6), color=blue, key="ponuda", explicit(q2(p),p,0,5.2),
color="#23ab0f",key="tocke ekvilibrija",point_type=filled_circle,point_size=2,
points([[3,5],[4/3,10/3]]),
yrange=[-4,8]),wxplot_size=[800,600];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,6],ytics=[-4,1,8],line_width=3,color=red,
key="potražnja",explicit(q1(p),p,0,6), color=blue, key="ponuda", explicit(q2(p),p,0,5.2),
color="#23ab0f",key="tocke ekvilibrija",point_type=filled_circle,point_size=2,
points([[3,5],[4/3,10/3]]),
yrange=[-4,8]);

c) dio

elastičnost potražnje u p=3

der1:diff(q1(p),p);

q1(3);

subst(3,p,der1);

3/q1(3)*subst(3,p,der1),numer;

INTERPRETACIJA: Ako na razini cijene p=3 cijenu povećamo za 1%, potražnja će se smanjiti za 2.4%.

elastičnost ponude u p=3

der2:diff(q2(p),p);

q2(3);

subst(3,p,der2);

3/q2(3)*subst(3,p,der2),numer;

INTERPRETACIJA: Ako na razini cijene p=3 cijenu povećamo za 1%, ponuda će se povećati za 0.6%.

## Zadatak

T(x):=0.001*x^3+10*x+2000;

a) dio

prosječni troškovi

Tp(x):=expand(T(x)/x);

Tp(x);

granični troškovi

Tg(x):=subst(x,y,diff(T(y),y));

Tg(x);

grafovi prosječnih i graničnih troškova

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,200],ytics=[0,25,200],line_width=3,color=red,
key="prosječni troškovi",explicit(Tp(x),x,0,200), color=blue, key="granični troškovi", explicit(Tg(x),x,0,200),
yrange=[0,200]),wxplot_size=[700,500];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,200],ytics=[0,25,200],line_width=3,color=red,
key="prosječni troškovi",explicit(Tp(x),x,0,200), color=blue, key="granični troškovi", explicit(Tg(x),x,0,200),
yrange=[0,200]);

b) dio

d:diff(Tp(x),x);

samo je jedna realna stacionarna točka x=100

solve(d=0,x);

druga derivacija u x=100 je veća od nule pa se radi o minimumu

d2:diff(Tp(x),x,2);

subst(100,x,d2);

prosječni minimalni troškovi su jednaki graničnim troškovima za x=100

[Tp(100),Tg(100)];

ODGOVOR: Prosječni troškovi su minimalni za 100 proizvoda. U tom slučaju su granični troškovi jednaki minimalnim prosječnim troškovima. 
Na grafu se prosječni i granični troškovi sijeku baš za x=100, tj. u točki (100,40).

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,200],ytics=[0,20,200],line_width=3,color=red,
key="prosječni troškovi",explicit(Tp(x),x,0,200), color=blue, key="granični troškovi", explicit(Tg(x),x,0,200),
point_size=2,color="#23ab0f",point_type=filled_circle,key="Tp(100)=Tg(100)",points([[100,40]]),
yrange=[0,200]),wxplot_size=[700,500];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,25,200],ytics=[0,20,200],line_width=3,color=red,
key="prosječni troškovi",explicit(Tp(x),x,0,200), color=blue, key="granični troškovi", explicit(Tg(x),x,0,200),
point_size=2,color="#23ab0f",point_type=filled_circle,key="Tp(100)=Tg(100)",points([[100,40]]),
yrange=[0,200]);

## Zadatak

T(Q):=2009+1000*(Q-2)/(3*Q+4);

a) dio

Tg(Q):=ratsimp(subst(Q,x,diff(T(x),x)))$

Tg(Q);

Tg(9),numer;

ili ako vam je nejasna gornja definicija od Tg(Q), možete i jednostavnije postupiti

dT:diff(T(Q),Q);

ratsimp(dT);

subst(9.0,Q,dT);

INTERPRETACIJA: Ako na razini proizvodnje Q=9 proizvodnju povećamo za 1 proizvod, troškovi će se povećati za 10.41 novčanih jedinica.

b) dio

T(9.0);

9/T(9.0)*Tg(9.0);

ili koristeći drugi način i varijablu dT

9/T(9.0)*subst(9.0,Q,dT);

INTERPRETACIJA: Ako na razini proizvodnje Q=9 proizvodnju povećamo za 1%, troškovi će se povećati za 0.0419%.

## Zadatak

Tp(Q):=(Q+2)/(Q+1);

a) dio

funkcija troškova

T(Q):=Q*Tp(Q);

T(Q);

funkcija graničnih troškova

diff(T(Q),Q);

ratsimp(%);

možemo sve u jednom retku odjedanput napraviti

ratsimp(diff(T(Q),Q));

b) dio

solve(Tp(Q)=1.05,Q);

T(19);

T(19.0);

ODGOVOR: Prosječni troškovi su jednak 1.05 na razini proizvodnje od 19 proizvoda.
U tom slučaju su troškovi jednaki 19.95 novčanih jedinica.

## Zadatak

definiramo svoju funkciju koja će nam odmah za zadane točke na izlazu dati obje normalne jednadžbe;
naravno, možemo zadatak rješavati korak po korak, ali od ovoga je višestruka korist - možemo tu istu funkciju i u drugim takvim zadacima koristiti da ne moramo ponovo sve pješice raditi

linearni_model(cijena,kolicina,a,b):=block([jedn1,jedn2],
                                     jedn1:lsum(i,i,cijena)*a+length(cijena)*b=lsum(i,i,kolicina),
                                     jedn2:lsum(i,i,cijena^2)*a+lsum(i,i,cijena)*b=lsum(i,i,cijena*kolicina),
                                     [jedn1,jedn2])$

jedn:linearni_model([200,150,120,100],[15,22,25,30],a,b);

solve(jedn,[a,b]);

float(%);

linearna funkcija koja najbolje aproksimira funkciju zadanu tablicom

q(p):=-162/1135*p+9838/227;

slika - pazite niti jedna točka iz tablice zapravo nije na dobivenom pravcu;
neke su točke jako blizu tog pravca pa se čini kao da su na njemu;
na primjer, q(150)=21.9295, što je jako blizu broju 22 iz tablice

[q(200.0),q(150.0),q(120.0),q(100.0)];

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[0,2,50],line_width=2,color=blue,
key="linearni model",explicit(q(p),p,0,220), color=red, key="tablica", point_size=1,point_type=filled_circle,
points([[200,15],[150,22],[120,25],[100,30]]),yrange=[0,50]),wxplot_size=[900,600];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[0,2,50],line_width=2,color=blue,
key="linearni model",explicit(q(p),p,0,220), color=red, key="tablica", point_size=1,point_type=filled_circle,
points([[200,15],[150,22],[120,25],[100,30]]),yrange=[0,50]);

a) dio

dnevno se maksimalno traži oko 43 jakne

q(0.0);

po cijeni od 110 kn traži se oko 28 jakni dnevno

q(110.0);

35 jakni dnevno se tra\v{z}i po cijeni od 58 kn i 43 lipe

solve(q(p)=35,p);

float(%);

slika s istaknutim točkama za p=110 i q=35-

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[0,2,50],line_width=2,color=blue,
key="linearni model",explicit(q(p),p,0,220), color=red, key="tablica", point_size=1,point_type=filled_circle,
points([[200,15],[150,22],[120,25],[100,30]]),color="#23ab0f",key="q(110)=27.64",point_type=5,point_size=1.5,
points([[110,27.6387665]]),point_type=4,key="q(58.43)=35",points([[58.43,35]]),
line_type=dots,key="",line_width=2,parametric(110,t,t,0,27.64),parametric(t,27.64,t,0,110),
parametric(58.42,t,t,0,35),parametric(t,35,t,0,60),
yrange=[0,50]),wxplot_size=[1100,700];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[0,2,50],line_width=2,color=blue,
key="linearni model",explicit(q(p),p,0,220), color=red, key="tablica", point_size=1,point_type=filled_circle,
points([[200,15],[150,22],[120,25],[100,30]]),color="#23ab0f",key="q(110)=27.64",point_type=5,point_size=1.5,
points([[110,27.6387665]]),point_type=4,key="q(58.43)=35",points([[58.43,35]]),
line_type=dots,key="",line_width=3,parametric(110,t,t,0,27.64),parametric(t,27.64,t,0,110),
parametric(58.43,t,t,0,35),parametric(t,35,t,0,58.43),
yrange=[0,50]);

b) dio

solve(2/dp=-162/1135,dp);

float(%);

ODGOVOR: Da bi se prodale dvije jakne više dnevno, cijenu treba smanjiti za 14 kuna i 1 lipu.
Nije uopće bitno po kojoj cijeni trenutno prodajemo jakne jer se radi o linearnoj funkciji.

c) dio

diff(q(p),p);

110/q(110)*(-162)/1135;

float(%);

ODGOVOR: Ako se cijena jakne na razini p=110 poveća za 1%, potražnja za jaknama se smanji za 0.568%.
Kako je elastičnost u točki p=110 po apsolutnoj vrijednosti strogo manja od 1, povećanjem cijene na
razini p=110 za 1%, prihod će se povećati.

## Zadatak

T(x):=0.00007*x^3-0.01*x^2+1.26*x+84;
p(x):=3.5-0.01*x;

a) dio

funkcija prihoda

P(x):=x*p(x);

P(x);

expand(P(x));

dobit = prihod - troškovi

D(x):=P(x)-T(x);

D(x);

expand(D(x));

b) dio

dobit za 40 plakata

D(40);

dobit za 150 plakata

D(150);

c) dio

der:diff(D(x),x);

solve(der=0,x);

float(%);

broj plakata ne može biti negativan pa uzimamo u obzir samo pozitivnu vrijednost x=103.28;
kako je druga derivacija negativna u toj točki, tada se zaista tu ostvaruje maksimum;

der2:diff(D(x),x,2);

subst(103.28,x,der2);

D(103.28);

ODGOVOR: Maksimalna dnevna dobit se ostvaruje za otprilike oko 103 prodanih plakata i iznosi 70 kuna i 23 lipe.

p(103.28);

ODGOVOR: Da bi studentice ostvarile maksimalnu dnevnu dobit, moraju plakate prodavati po 2 kune i 47 lipa.

d) dio

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[-50,10,100],line_width=2,color=blue,
key="Dobit",explicit(D(x),x,0,200), color=red, key="maksimalna dobit", point_size=1.5,point_type=filled_circle,
points([[103.28,70.23]]),line_type=dots,key="",line_width=2,parametric(103.28,t,t,0,70.23),parametric(t,70.23,t,0,103.28),
label(["103.28",103.28,-3],["70.23",5,73]),yrange=[-50,100]),wxplot_size=[1100,700];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,10,220],ytics=[-50,10,100],line_width=2,color=blue,
key="Dobit",explicit(D(x),x,0,200), color=red, key="maksimalna dobit", point_size=1.5,point_type=filled_circle,
points([[103.28,70.23]]),line_type=dots,key="",line_width=3,parametric(103.28,t,t,0,70.23),parametric(t,70.23,t,0,103.28),
label(["103.28",103.28,-3],["70.23",5,73]),yrange=[-50,100]);

ODGOVOR: Gledajući sliku i rezultate iz b) dijela zadatka, možemo zaključiti da studentice dnevno moraju prodavati između 40 i 150 plakata kako ne bi imale dnevni gubitak. Naravno, najbolje je da je dnevni broj prodanih kalendara što bliže broju 103 (jer se u njegovoj blizini postiže maksimalna dnevna dobit).

Želimo li baš dati precizni rezultat do kraja, morali bismo pronaći nultočke funkcije D(x) (ili otprilike što je moguće točnije sa slike dati što bolju procjenu). Ručno nam ne bi bilo ugodno tražiti nultočke jer se radi o jednadžbi trećeg stupnja, ali pomoću maksime možemo i to bez problema obaviti. Pritom nas negativna nultočka ne zanima jer broj plakata ne može biti negativan broj.

allroots(D(x));

PRECIZNIJI ODGOVOR: Studentice dnevno moraju prodati između 40 i 155 plakata, kako ne bi imale dnevnih gubitaka. Naravno, kada rješavate ručno zadatak bez ovog programa, tada je i onaj prethodni odgovor zadovoljavajući jer ionako nam je stalo da broj prodanih plakata bude što je moguće bliži broju 103.

CIJENA: cijena ovisi padajuće linearno o broju plakata x; iskoristimo li podatke iz b) dijela zadatka zaključujemo da cijena plakata mora biti otprilike između 2 kune i 3 kune 1 lipe kako bi studentice imale dnevnu pozitivnu dobit.

[p(40),p(150)];

CIJENA - precizniji interval ako iskoristimo pozitivne nultočke funkcije dobiti:
Cijena plakata mora biti između 1 kune 94 lipa i 3 kune i 11 lipa kako bi studentice imale dnevnu pozitivnu dobit.

[p(39.413276),p(155.892181)];

NAPOMENA: Dobiveni maksimum je samo lokalnog karaktera za funkciju dobiti na njezinoj prirodnoj domeni. Ako pogledate donju sliku, vidjet ćete da ona postiže i veće vrijednosti od 70.23, samo se to događa na negativnom dijelu domene, a zbog prirode problema nas negativni dio domene ne zanima (jer broj plakata ne može biti negativan broj). No, na pozitivnom dijelu domene to je globalni maksimum.
Isto tako možete uočiti i lokalni minimum u točki x=-103.28, samo smo tu točku bili izbacili iz razmatranja jer broj plakata ne može biti negativan broj.

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[-250,50,250],ytics=[-300,50,300],line_width=2,color=blue,
explicit(D(x),x,-250,250),yrange=[-300,300]),wxplot_size=[800,600];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[-250,50,250],ytics=[-300,50,300],line_width=2,color=blue,
explicit(D(x),x,-250,250),yrange=[-300,300]);

## Zadatak

q(p):=(2*p+1)*log(5*p)/log(4);

a) dio

derivacija funkcije ponude

der:diff(q(p),p);

ratsimp(der);

vrijednosti ponude i njezine derivacije za p=10

q(10),numer;

subst(10,p,der),numer;

elastičnost ponude za p=10

10/q(10)*subst(10,p,der),numer;

INTERPRETACIJA: Ako na razini cijene p=10 cijenu povećamo za 1%, ponuda će se povećati za 1.208%.

b) dio

q(18),numer;

ODGOVOR: Po cijeni od 18 novčanih jedinica nudi se oko 120 proizvoda.

subst(18,p,der),numer;

18/q(18)*subst(18,p,der),numer;

ODGOVOR: Kako je za p=18 elastičnost po apsolutnoj vrijednosti veća od 1, ponuda je elastična za p=18.

## Zadatak

T(Q):=100*(3*Q+2007)/sqrt(3*Q+2007);

a) dio

funkcija graničnih troškova

der:diff(T(Q),Q);

granični troškovi za Q=10

subst(10.0,Q,der);

INTERPRETACIJA: Ako na razini proizvodnje Q=10 proizvodnju povećamo za 1 proizvod, 
troškovi će se povećati za 3.32 novčane jedinice.

b) dio

solve(T(Q)=5000,Q);

float(%);

ODGOVOR: Da bi troškovi bili jednaki 5000, treba proizvesti oko 164 proizvoda.

## Zadatak

T(Q):=(Q^2+1000)/(Q+1);

a) dio

fiksni troškovi - troškovi za 0 proizvoda (kada još nema proizvodnje)

T(0);

varijabilni troškovi = troškovi - fiksni troškovi

T(Q)-T(0);

ratsimp(%);

b) dio

funkcija graničnih troškova

der:diff(T(Q),Q);

ratsimp(der);

vrijednost troškova i graničnih troškova za Q=35

T(35.0);

subst(35.0,Q,der);

elastičnost troškova za Q=35

35/T(35.0)*subst(35.0,Q,der);

ODGOVOR: Ako na razini proizvodnje Q=35 proizvodnju povećamo za 1%, troškovi će se povećati za 0.1289%.

## Zadatak

Q(p):=2005+25*0.7^p;

a) dio

derivacija funkcije potražnje

der:diff(Q(p),p);

vrijednost potražnje i njezine derivacije za p=4

Q(4);

subst(4,p,der);

elastičnost potražnje za p=4

4/Q(4)*subst(4,p,der);

INTERPRETACIJA: Ako na razini cijene p=4 cijenu povećamo za 1%, potražnja će se smanjiti za 0.004%.

b) dio

Kako je elastičnost za p=4 po apsolutnoj vrijednosti manja od 1, ako se cijena na razini p=4
poveća za 1%, prihod će se povećati.

## Zadatak

q(p):=900-3*p;

a) dio

200/q(200)*(-3);

ODGOVOR: Kako je elastičnost ove funkcije za p=200 po apsolutnoj vrijednosti veća od 1,
zadana funkcija je elastična za p=200.

b) dio

ODGOVOR: Kako je elastičnost ove funkcije za p=200 po apsolutnoj vrijednosti veća od 1,
želimo li povećati prihod, moramo smanjiti cijenu.

c) dio

funkcija prihoda

P(p):=p*q(p);

P(p);

pomoću derivacije pronađemo ekstreme funkcije prihoda

der:diff(P(p),p);

solve(der=0,p);

kako je druga derivacija za p=150 negativna, radi se o maksimumu

der2:diff(P(p),p,2);

subst(150,p,der2);

maksimalni prihod

P(150);

ODGOVOR: Maksimalni prihod se ostvaruje uz cijenu od 150 kn i iznosi 67500 kn.

graf funkcije prihoda

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="prihod",xtics=[0,10,300],ytics=[0,5000,80000],line_width=2,color=blue,
key="prihod",explicit(P(p),p,0,300), color=red, key="maksimalni prihod=67500", point_size=1.5,point_type=filled_circle,
points([[150,67500]]),yrange=[0,80000]),wxplot_size=[1200,600];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="prihod",xtics=[0,10,300],ytics=[0,5000,80000],line_width=2,color=blue,
key="prihod",explicit(P(p),p,0,300), color=red, key="maksimalni prihod=67500", point_size=1.5,point_type=filled_circle,
points([[150,67500]]),yrange=[0,80000]);

## Zadatak

q(p):=(4*p-2)^(1/4);

a) dio

derivacija funkcije ponude

der:diff(q(p),p);

vrijednost funkcije ponude i njezine derivacije za p=20

q(20.0);

subst(20.0,p,der);

elastičnost ponude za p=20

20/q(20.0)*subst(20.0,p,der);

INTERPRETACIJA: Ako na razini cijene p=20 cijenu povećamo za 1%, ponuda će se povećati za 0.25641%.

b) dio

solve(q(p)=10,p);

float(%);

ODGOVOR: Po cijeni od 2500.5 novčanih jedinica ponudit će se točno 10 proizvoda.

c) dio

elast:p/q(p)*der;

solve(elast=0.26,p);

ODGOVOR: Elastičnost ponude je jednaka 0.26 na razini cijene p=13.

## Zadatak

a) dio

solve([10*a+b=27000,8*a+b=33000],[a,b]);

q(p):=-3000*p+57000;

b) dio

funkcija prihoda

P(p):=p*q(p);

expand(P(p));

pomoću derivacije pronađemo ekstreme funkcije prihoda

der:diff(P(p),p);

solve(der=0,p);

float(%);

kako je druga derivacija za p=9.5 negativna, radi se o maksimumu

der2:diff(P(p),p,2);

subst(9.5,p,der2);

maksimalni prihod

P(9.5);

ODGOVOR: Ulaznice treba prodavati po cijeni od 9.5 eura da bi se postigao maksimalni prihod od 270750 eura.

graf funkcije prihoda

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="prihod",xtics=[0,1,20],ytics=[0,50000,280000],line_width=2,color=blue,
key="prihod",explicit(P(p),p,0,20), color=red, key="maksimalni prihod=270750", point_size=1.5,point_type=filled_circle,
points([[9.5,270750]]),yrange=[0,280000]),wxplot_size=[900,600];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="prihod",xtics=[0,1,20],ytics=[0,50000,280000],line_width=2,color=blue,
key="prihod",explicit(P(p),p,0,20), color=red, key="maksimalni prihod=270750", point_size=1.5,point_type=filled_circle,
points([[9.5,270750]]),yrange=[0,280000]);

## Zadatak

T(x):=3*x^2+x+48;

a) dio

prosječni troškovi

Tp(x):=T(x)/x;

expand(Tp(x));

pomoću prve derivacije tražimo stacionarne točke funkcije Tp

der:diff(Tp(x),x);

ratsimp(der);

u obzir dolazi samo x=4 jer broj proizvoda ne može biti negativan broj

solve(der=0,x);

druga derivacija u x=4 je pozitivna pa se radi o minimumu

der2:diff(Tp(x),x,2);

ratsimp(der2);

subst(4,x,der2);

minimalni prosječni troškovi

Tp(4);

ODGOVOR: Prosječni troškovi su minimalni za 4 proizvoda i iznose 25 novčanih jedinica.

b) dio

granični troškovi

gr:diff(T(x),x);

za koji x vrijedi prosječni troškovi = granični troškovi?

solve(Tp(x)=gr,x);

ODGOVOR: Prosječni troškovi su jednaki graničnim troškovima za 4 proizvoda. 

c) dio

prosječni i granični troškovi na jednoj slici

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,10],ytics=[0,5,100],line_width=2,color=blue,
key="prosječni troškovi",explicit(Tp(x),x,0,10),color=red,key="granični troškovi",explicit(6*x+1,x,0,9.8),
key="min Tp=25",point_size=1.5,point_type=filled_circle,color=blue,
points([[4,25]]),yrange=[0,100]),wxplot_size=[800,600];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,10],ytics=[0,5,100],line_width=2,color=blue,
key="prosječni troškovi",explicit(Tp(x),x,0,10),color=red,key="granični troškovi",explicit(6*x+1,x,0,9.8),
key="min Tp=25",point_size=1.5,point_type=filled_circle,color=blue,
points([[4,25]]),yrange=[0,100]);

troškovi, prosječni troškovi i granični troškovi na jednoj slici

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,10],ytics=[0,25,250],line_width=2,color=blue,
key="prosječni troškovi",explicit(Tp(x),x,0,10),color=red,key="granični troškovi",explicit(6*x+1,x,0,9.8),
color=brown,key="troškovi",explicit(T(x),x,0,9),
key="min Tp=25",point_size=1.5,point_type=filled_circle,color=blue,
points([[4,25]]),yrange=[0,250]),wxplot_size=[800,600];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,1,10],ytics=[0,25,250],line_width=2,color=blue,
key="prosječni troškovi",explicit(Tp(x),x,0,10),color=red,key="granični troškovi",explicit(6*x+1,x,0,9.8),
color=brown,key="troškovi",explicit(T(x),x,0,9),
key="min Tp=25",point_size=1.5,point_type=filled_circle,color=blue,
points([[4,25]]),yrange=[0,250]);

## Zadatak

a) dio

solve([a=-2/1,a*10+b=20],[a,b]);

q(p):=-2*p+40;

b) dio

prihod

P(p):=p*q(p);

expand(P(p));

dobit (profit) = prihod - troškovi

D(p):=P(p)-6*q(p);

D(p);

expand(D(p));

pomoću prve derivacije tražimo stacionarne točke funkcije dobiti

der:diff(D(p),p);

solve(der=0,p);

druga derivacija za p=13 je manja od nule pa se radi o maksimumu

der2:diff(D(p),p,2);

subst(13,p,der2);

maksimalni profit (dobit)

D(13);

broj prodanih ogrlica kod maksimalnog profita

q(13);

ODGOVOR: Student mora prodavati ogrlice po 13 eura ako želi ostvariti maksimalni profit
koji iznosi 98 eura. U tom slučaju će prodati 14 ogrlica.

## Zadatak

N(p):=1500/(p^2+100);
T(p):=2*N(p)+14;

profit = prihod - troškovi

D(p):=p*N(p)-T(p);

ratsimp(D(p));

pomoću prve derivacije tražimo stacionarne točke funkcije profita

der:diff(D(p),p);

ratsimp(der);

u obzir uzimamo samo pozitivno rješenje p=12.2

solve(der=0,p);

float(%);

druga derivacija za p=12.2 je negativna pa se radi o maksimumu

der2:diff(D(p),p,2);

ratsimp(der2);

subst(12.2,p,der2);

maksimalni profit

D(12.2);

ODGOVOR: Maksimalni profit iznosi 47.49 novčanih jedinica i ostvaruje se uz cijenu od 12.2 novčane jedinice.

graf funkcije profita na segmentu [3,100]

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,5,100],ytics=[0,5,100],line_width=2,color=blue,
key="profit",explicit(D(p),p,0,100),color=red,key="maksimalni profit",point_size=1.5,point_type=filled_circle,
points([[12.198,47.485]]),key="",line_type=dots,line_width=2, parametric(12.198,t,t,0,47.485),parametric(t,47.485,t,0,12.198),
label(["12.2",14.5,2],["47.49",3,48.5]),yrange=[0,60]),wxplot_size=[1000,700];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[0,5,100],ytics=[0,5,100],line_width=2,color=blue,
key="profit",explicit(D(p),p,0,100),color=red,key="maksimalni profit",point_size=1.5,point_type=filled_circle,
points([[12.198,47.485]]),key="",line_type=dots,parametric(12.198,t,t,0,47.485),parametric(t,47.485,t,0,12.198),
label(["12.2",13.5,2],["47.49",3,48.5]),yrange=[0,60]);

graf funkcije profita na [-500,500]. Uočavamo da ima i minimum koji se postiže na negativnom dijelu domene (to je ona točka p=-8.2 koju smo gore zbog prirode problema izbacili iz razmatranja), a ima i horizontalnu asimptotu y=-14

limit(D(p),p,inf);

limit(D(p),p,minf);

wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[-500,50,500],ytics=[-120,10,60],line_width=2,color=red,
key="profit",explicit(D(p),p,-500,500),color=blue,line_type=dots,line_width=2,key="horizontalna asimptota: y=-14",
parametric(t,-14,t,-500,500),yrange=[-120,60]),wxplot_size=[1200,700];

draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="p",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="",xtics=[-500,50,500],ytics=[-120,10,60],line_width=2,color=red,
key="profit",explicit(D(p),p,-500,500),color=blue,line_type=dots,line_width=3,key="horizontalna asimptota: y=-14",
parametric(t,-14,t,-500,500),yrange=[-120,60]);