(%i2) load(fourier_elim)$
load(draw)$

1 Domena funkcije

1. zadatak

(%i3) f(x):=(log((x-1)/(3-2*x)-2)/log(1/2))^(1/2);
(%o3) f(x):=(log((x-1)/(3-2*x)-2)/log(1/2))^(1/2)
(%i4) fourier_elim([(x-1)/(3-2*x)-2>0],[x]);
(%o4) [7/5<x,x<3/2]
(%i5) fourier_elim([log((x-1)/(3-2*x)-2)/log(1/2)>=0],[x]);
(%o5) [log(-(5*x-7)/(2*x-3))=0] or [-log(-(5*x-7)/(2*x-3))>0]
(%i6) fourier_elim([(x-1)/(3-2*x)-2>0,(5*x-7)/(3-2*x)<=1],[x]);
(%o6) [x=10/7] or [7/5<x,x<10/7]

2. zadatak

(%i7) f(x):=(log(x+5)^2/log(10))^(-1);
(%o7) f(x):=1/(log(5+x)^2/log(10))
(%i8) fourier_elim([(x+5)^2>0,(x+5)^2#1],[x]);
(%o8) [-6<x,x<-5] or [-5<x,x<-4] or [-4<x] or [x<-6]

3. zadatak

(%i9) f(x):=sqrt(-x)+(2+x)^(-1/2);
(%o9) f(x):=(2+x)^((-1)/2)+sqrt(-x)
(%i10) fourier_elim([-x>=0,2+x>0],[x]);
(%o10) [x=0] or [-2<x,x<0]

4. zadatak

(%i11) f(x):=log(log(log(x+1)/log(2))/log(4))/log(8);
(%o11) f(x):=log(log(log(1+x)/log(2))/log(4))/log(8)
(%i12) fourier_elim([x+1>0,log(x+1)/log(2)>0,log(log(x+1)/log(2))/log(4)>0],[x]);
(%o12) [-1<x,log(log(x+1)/log(2))>0,log(x+1)>0]
(%i13) fourier_elim([x>-1,log(x+1)/log(2)>1,x+1>1], [x]);
(%o13) [0<x,log(x+1)-log(2)>0]
(%i14) fourier_elim([x>0,x+1>2],[x]);
(%o14) [1<x]

5. zadatak (samo je prikazan na slici crvenom bojom jedan dio domene)

(%i15) f(x):=sqrt(sin(2*x));
(%o15) f(x):=sqrt(sin(2*x))
(%i16) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="y",line_width=3,color=blue,
xtics=[-2*%pi,%pi/2,2*%pi],key="sin(2x)",
explicit(sin(2*x),x,-7,7),color=red,key="domena",explicit(0,x,0,%pi/2),key="",explicit(0,x,%pi,3*%pi/2),
explicit(0,x,-%pi,-%pi/2),xrange=[-4,6],yrange=[-2,2]), wxplot_size=[700,400];
(%t16)
(Graphics)
(%o16)
(%i17) draw2d(terminal=wxt,grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="y",line_width=3,color=blue,
xtics=[-2*%pi,%pi/2,2*%pi],key="sin(2x)",
explicit(sin(2*x),x,-7,7),color=red,key="domena",explicit(0,x,0,%pi/2),key="",explicit(0,x,%pi,3*%pi/2),
explicit(0,x,-%pi,-%pi/2),xrange=[-4,6],yrange=[-2,2]);
(%o17) [gr2d(explicit,explicit,explicit,explicit)]

2 Domena i nultočke

1. zadatak

(%i18) f(x):=(2*sqrt(x))/(3-x^2);
(%o18) f(x):=(2*sqrt(x))/(3-x^2)
(%i19) fourier_elim([x>=0,(x-sqrt(3))*(x+sqrt(3))#0],[x]);
(%o19) [x=0] or [0<x,x<sqrt(3)] or [sqrt(3)<x]
(%i20) solve(f(x)=0,x);
(%o20) [x=0]

2. zadatak (domena je čitav skup realnih brojeva, a realnih nultočaka nema)

(%i21) f(x):=sqrt(x^2+x+5);
(%o21) f(x):=sqrt(5+x+x^2)
(%i22) fourier_elim([x^2+x+5>=0],[x]);
(%o22) [x^2+x+5=0] or [x^2+x+5>0]
(%i23) solve(x^2+x+5=0,x);
(%o23) [x=-(1+sqrt(19)*%i)/2,x=(sqrt(19)*%i-1)/2]
(%i24) wxplot2d([x^2+x+5], [x,-5,5],[y,-5,20])$
plot2d: some values were clipped.
(%t24)
(Graphics)
(%i25) solve(f(x)=0,x);
(%o25) [x=-(1+sqrt(19)*%i)/2,x=(sqrt(19)*%i-1)/2]

3. zadatak

(%i26) f(x):=log((x-2)/(3-x))/log(1/2);
(%o26) f(x):=log((x-2)/(3-x))/log(1/2)
(%i27) fourier_elim([(x-2)/(3-x)>0],[x]);
(%o27) [2<x,x<3]
(%i28) solve(f(x)=0,x);
(%o28) [x=5/2]

4. zadatak

(%i29) f(x):=%e^((log(5-x))/(x^2-4));
(%o29) f(x):=%e^(log(5-x)/(x^2-4))
(%i30) fourier_elim([5-x>0,x^2-4#0],[x]);
(%o30) [-2<x,x<2] or [2<x,x<5] or [x<-2]
(%i31) solve(f(x)=0,x);
(%o31) []

3 Injekcija, surjekcija, bijekcija

1. zadatak

(%i32) f(x):=2^(x+3);
(%o32) f(x):=2^(x+3)
(%i33) wxplot2d ( 2^(x+3), [x, -3, 2], [y, -2, 15], [style, [lines,4]])$
plot2d: some values were clipped.
(%t33)
(Graphics)

2. zadatak

(%i34) f(x):=log(4*x^2)/log(2);
(%o34) f(x):=log(4*x^2)/log(2)
(%i35) wxplot2d ( log(4*x^2)/log(2), [x, -3, 3], [style, [lines,4]])$
plot2d: expression evaluates to non-numeric value somewhere in plotting range.
(%t35)
(Graphics)

3. zadatak

(%i36) f(x):=3/(3*x^2+1);
(%o36) f(x):=3/(1+3*x^2)
(%i37) wxplot2d ( 3/(3*x^2+1), [x, -3, 3],[y,0,5], [style, [lines,4]])$
(%t37)
(Graphics)

4. zadatak

(%i38) f(x):=x/(4-2*x);
(%o38) f(x):=x/(4-2*x)
(%i39) wxplot2d ( [x/(4-2*x),-1/2], [x, -8, 6],[y,-10,10],[style, [lines,3]])$
plot2d: some values were clipped.
(%t39)
(Graphics)

4 Kompozicija funkcija

1. zadatak

(%i41) f(x):=(2*x)/(x-5);
g(x):=1-x;
(%o40) f(x):=(2*x)/(x-5)
(%o41) g(x):=1-x
(%i42) f(g(x));
(%o42) (2*(1-x))/(-x-4)
(%i43) g(f(x));
(%o43) 1-(2*x)/(x-5)
(%i44) factor(g(f(x)));
(%o44) -(5+x)/(x-5)

2. zadatak

(%i46) f(x):=log(4*x^2)/log(2);
g(x):=2^(x+3);
(%o45) f(x):=log(4*x^2)/log(2)
(%o46) g(x):=2^(x+3)
(%i47) f(g(x));
(%o47) 2*(3+x)+2
(%i48) expand(f(g(x)));
(%o48) 2*x+8
(%i49) g(f(x));
(%o49) 2^(3+log(4*x^2)/log(2))
(%i50) radcan((g(f(x))));
(%o50) 32*x^2

3. zadatak

(%i52) f(x):=(2*x+3)/(3*x+2);
g(x):=x/(4-2*x);
(%o51) f(x):=(3+2*x)/(2+3*x)
(%o52) g(x):=x/(4-2*x)
(%i53) f(g(x));
(%o53) (3+(2*x)/(4-2*x))/((3*x)/(4-2*x)+2)
(%i54) ratsimp(f(g(x)));
(%o54) (4*x-12)/(x-8)
(%i55) g(f(x));
(%o55) (3+2*x)/((3*x+2)*(4-(2*(3+2*x))/(3*x+2)))
(%i56) ratsimp(g(f(x)));
(%o56) (3+2*x)/(8*x+2)

5 Inverzna funkcija

1. zadatak

(%i57) f(x):=(2*x-1)/(1-x);
(%o57) f(x):=(2*x-1)/(1-x)
(%i58) solve(f(x)=y,x);
(%o58) [x=(1+y)/(y+2)]
(%i59) wxplot2d([f(x),(x+1)/(x+2),x],[x, -8, 6],[y,-10,10],[style, [lines,3]])$
plot2d: some values were clipped.plot2d: some values were clipped.<BR>
(%t59)
(Graphics)

2. zadatak

(%i60) f(x):=5^(1-x/3);
(%o60) f(x):=5^(1-x/3)
(%i61) solve(f(x)=y,x);
(%o61) [x=-(3*log(y)-3*log(5))/log(5)]
(%i62) wxplot2d([f(x),3-3*log(x)/log(5),x],[x, 0.1, 6],[y,-1,10],[style, [lines,3]])$
(%t62)
(Graphics)

3. zadatak

(%i63) f(x):=log(x)/log(3)+2;
(%o63) f(x):=2+log(x)/log(3)
(%i64) solve(f(x)=y,x);
(%o64) [x=%e^(log(3)*y)/9]
(%i65) wxplot2d([f(x),3^(x-2),x],[x, 0.1, 6],[y,-1,10],[style, [lines,3]])$
plot2d: some values were clipped.
(%t65)
(Graphics)

4. zadatak

(%i66) f(x):=log(x+2)/log(3);
(%o66) f(x):=log(2+x)/log(3)
(%i67) solve(f(x)=y,x);
(%o67) [x=%e^(log(3)*y)-2]
(%i68) wxplot2d([f(x),3^x-2,x],[x, -5, 6],[y,-5,10],[style, [lines,3]])$
plot2d: expression evaluates to non-numeric value somewhere in plotting range.plot2d: some values were clipped.<BR> plot2d: some values were clipped.<BR>
(%t68)
(Graphics)

5. zadatak

(%i69) f(x):=(x+1)^(1/2);
(%o69) f(x):=(x+1)^(1/2)
(%i70) solve(f(x)=y,x);
"Is "y" positive, negative or zero?"p;
(%o70) [x=y^2-1]
(%i71) wxplot2d([f(x),x^2-1,x],[x, -1, 6],[y,-2,5],[style, [lines,3]])$
plot2d: some values were clipped.plot2d: some values were clipped.<BR>
(%t71)
(Graphics)

preciznija slika

(%i72) wxdraw2d(grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x", proportional_axes=xy,
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="y",line_width=3,color=blue,
explicit((x+1)^(1/2),x,-1,6),color=red,explicit(x^2-1,x,0,5),color=green,explicit(x,x,-2,6),
xrange=[-2,6],yrange=[-2,10]),wxplot_size=[400,400];
(%t72)
(Graphics)
(%o72)
(%i73) draw2d(terminal=wxt, grid=true,xaxis=true,xaxis_width=1,xaxis_type=solid,xlabel="x",
yaxis=true,yaxis_width=1,yaxis_type=solid,ylabel="y",line_width=3,color=blue,
explicit((x+1)^(1/2),x,-1,6),color=red,explicit(x^2-1,x,0,5),color=green,explicit(x,x,-2,6),
xrange=[-2,6],yrange=[-2,10]);
(%o73) [gr2d(explicit,explicit,explicit)]

6 Omeđenost i monotonost

1. zadatak

(%i74) f(x):=2*sqrt(x)/(3-x^2);
(%o74) f(x):=(2*sqrt(x))/(3-x^2)
(%i75) wxplot2d(f(x),[x, 0, 6],[y,-20,20],[style, [lines,3]])$
plot2d: some values were clipped.
(%t75)
(Graphics)

2. zadatak

(%i76) f(x):=sqrt(x+5);
(%o76) f(x):=sqrt(5+x)
(%i77) wxplot2d(f(x),[x, -6, 20],[y,-2,6],[style, [lines,3]])$
plot2d: expression evaluates to non-numeric value somewhere in plotting range.
(%t77)
(Graphics)

3. zadatak

(%i78) f(x):=4/(x^2+3);
(%o78) f(x):=4/(3+x^2)
(%i79) wxplot2d(f(x),[x, -6, 6],[y,-2,3],[style, [lines,3]])$
(%t79)
(Graphics)

4. zadatak

(%i80) f(x):=%e^(5-x);
(%o80) f(x):=%e^(5-x)
(%i81) wxplot2d(f(x),[x, -2, 3],[y,-100,1200],[style, [lines,3]])$
(%t81)
(Graphics)

5. zadatak

(%i82) f(x):=3*sin(2*x+%pi);
(%o82) f(x):=3*sin(%pi+2*x)
(%i83) wxplot2d(f(x),[x, -6, 6],[y,-4,4],[style, [lines,3]])$
(%t83)
(Graphics)

7 Parnost, neparnost

1. zadatak

(%i84) f(x):=2*x^2/(3-x^2);
(%o84) f(x):=(2*x^2)/(3-x^2)
(%i85) f(-x);
(%o85) (2*x^2)/(3-x^2)
(%i86) wxplot2d(f(x),[x, -6, 6],[y,-10,10],[style, [lines,3]])$
plot2d: some values were clipped.
(%t86)
(Graphics)

2. zadatak

(%i87) f(x):=(x+5*x^5)^(1/3);
(%o87) f(x):=(x+5*x^5)^(1/3)
(%i88) f(-x);
(%o88) (-x-5*x^5)^(1/3)
(%i89) wxplot2d(f(x),[x, -3, 3],[y,-4,4],[style, [lines,3]])$
plot2d: some values were clipped.
(%t89)
(Graphics)
(%i90) wxplot2d(f(-x),[x, -3, 3],[y,-4,4],[style, [lines,3]])$
plot2d: some values were clipped.
(%t90)
(Graphics)

3. zadatak

(%i91) f(x):=%e^(5-x);
(%o91) f(x):=%e^(5-x)
(%i92) f(-x);
(%o92) %e^(5+x)
(%i93) wxplot2d(f(x),[x, -2, 3],[y,-100,1200],[style, [lines,3]])$
(%t93)
(Graphics)

4. zadatak

(%i94) f(x):=abs(x-4)+abs(x+4);
(%o94) f(x):=abs(4+x)+abs(x-4)
(%i95) f(-x);
(%o95) abs(x+4)+abs(x-4)
(%i96) wxplot2d(f(x),[x, -10, 10],[y,-1,20],[style, [lines,3]])$
(%t96)
(Graphics)

5. zadatak

(%i97) f(x):=cos(x^5)/x+sin(x^10)/x;
(%o97) f(x):=sin(x^10)/x+cos(x^5)/x
(%i98) f(-x);
(%o98) -sin(x^10)/x-cos(x^5)/x
(%i99) wxplot2d(f(x),[x, -3, 3],[y,-10,10],[style, [lines,2]])$
plot2d: expression evaluates to non-numeric value somewhere in plotting range.plot2d: some values were clipped.<BR>
(%t99)
(Graphics)
Created with wxMaxima.