## Generiranje matrice

Generiranje matrice čiji elementi su zadani nekom formulom

T: genmatrix(lambda([i,j],i-j), 5,4);

M: genmatrix(lambda([i,j], if i>j then cos(i*%pi/2) else log(i+j)/log(2)), 3, 4);

## Operacije s matricama

1. zadatak

A: matrix(
 [1,2], 
 [0,-3], 
 [5,4]
);

B:matrix(
 [1,0,-2,5], 
 [8,4,-1,3]
);

A.B;

B.A;

transpose(A);

2. zadatak

A: matrix(
 [3,1,-4], 
 [-4,6,-2], 
 [5,8,5]
);

B: matrix(
 [3,7,-4], 
 [2,1,0], 
 [-5,3,2]
);

A.B;

B.A;

3*A.B-7*B.A;

3. zadatak

A: matrix([3,-2],[-1,5]);

A^^2;

A^^3;

diag_matrix(1,1);

A^^3+2*A^^2+3*diag_matrix(1,1);

Oprez. Uočite razliku između sljedećih operacija

A: matrix([3,1,-4],[-4,6,-2],[5,8,5]);

B: matrix([3,7,-4],[2,1,0],[-5,3,2]);

Oprez: * (zvjezdica) samo množi matrice po pozicijama

A*B;

B*A;

Pomoću . (točkica) maxima vrši pravo množenje matrica 

A.B;

B.A;

Oprez: ^ samo potencira matrice po elementima

A^2;

^^ obavlja pravo potenciranje matrica

A^^2;

ako ne želimo ispisati matrice

A: matrix([3,1,-4],[-4,6,-2],[5,8,5])$

B: matrix([3,7,-4],[2,1,0],[-5,3,2])$

4. zadatak

A: matrix([2,-2,0],[1,-2,1])$
B: matrix([2],[1],[3])$

A.B;

5. zadatak

A: matrix([2,3],[1,5])$
B: 9/5*matrix([1,0,4],[3,6,8])$

A.B;

## Determinante

1. zadatak

A: matrix([2,5],[1,-3]);
B: matrix([x-a,-a],[a,x+a]);
C: matrix([sin(a),cos(a)],[sin(b),cos(b)]);

determinant(A);

determinant(B);

expand(determinant(B));

determinant(C);

trigreduce(determinant(C));

možemo i direktno izračunati determinatu bez spremanja matrice u varijablu

determinant(matrix([2,5],[1,-3]));

2. zadatak

A: matrix([9,4,-5],[8,7,-2],[2,-1,8])$

determinant(A);

3. zadatak

A: matrix([2,-5,1,2],[-3,7,-1,4],[5,-9,2,7],[4,-6,1,2])$

determinant(A);

4. zadatak

A: matrix([3,a,3,a],[6,3,6,3],[7,7,6,6],[a,5,a,5])$

determinant(A);

expand(determinant(A));

mogli smo determinantu spremiti u neku varijablu i zatim pojednostavniti taj izraz 

izraz: determinant(A);

expand(izraz);

5. zadatak

A: matrix([a,a,a,a,a],[-2,a,a,a,a],[2,0,a,a,a],[-4,0,0,a,a],[4,0,0,0,a])$

determinant(A);

6. zadatak

A: matrix([4+x,2,2],[7,x-1,2],[x+1,5,5]);

det: determinant(A);

pojednostavljenje izraza za determinantu

expand(det);

rješavanje jednadžbe det(A)=0

solve(expand(det)=0,x);

računanje izraza det(A^T)+5*det(A^3)-2*det(1/2*A) za x=-1

rezultat2: determinant(transpose(A))+5*determinant(A^^3)-2*determinant(1/2*A);

expand(rezultat2);

subst(-1,x,expand(rezultat2));

mogli smo najprije x=-1 uvrstiti u matricu A kako smo to radili i na seminarima

B: subst(-1,x,A);

determinant(transpose(B))+5*determinant(B^^3)-2*determinant(1/2*B);

7. zadatak

A: matrix([x-3,3,3,3],[3,2*x+3,3,3],[3,3,x-3,3],[3,3,3,2*x+3]);

determinant(A);

izraz: expand(determinant(A));

solve(izraz=0,x);

## Inverzna matrica

1. zadatak

A: matrix([2,1],[-5,4]);

dva načina traženja inverza matrice

invert(A);

A^^-1;

Oprez: Dolje navedena naredba samo daje matricu inverznih elemenata, a ne inverznu matricu matrice A

A^-1;

želimo li kod invertiranja matrice determinantu izlučiti izvan matrice

detout: true$
doallmxops: false$
doscmxops: false$
invert(A);

jednom kad smo varijablu detout postavili na true, tada samo mijenjanjem vrijednosti varijable doallmxops prelazimo iz jednog u drugi način pisanja inverza matrice

doallmxops: true$

invert(A);

mogli smo i jednostavnije izlučiti determinantu izvan inverzne matrice tako da posebno odredimo adjunktu, a posebno determinantu

adjoint(A);

determinant(A);

2. zadatak

B: 2/3*matrix([3,5],[1,-3]);

B^^-1;

3. zadatak

E: matrix([-3,4,-5],[4,-3,2],[1,-3,4]);

invert(E);

doallmxops: false$
invert(E);

adjunkta i determinanta

adjoint(E);

determinant(E);

4. zadatak

A: 5/3*matrix([1,5,8],[2,3,-1],[4,-5,-9]);

problem???

invert(A);

rješenje problema: treba barem jednu od varijabli doallmxops ili doscmxops postaviti na true

doscmxops: true$
A: 5/3*matrix([1,5,8],[2,3,-1],[4,-5,-9]);

invert(A);

želimo li determinatu izlučiti izvan matrice tada moramo varijablu doscmxops postaviti na false (jer smo ju maloprije gore postavili na true)

doscmxops: false$
invert(A);

doallmxops: true$

5. zadatak

[A: matrix([a,1,-1],[-1,1,1],[-2,0,0]),B: matrix([1,0,0],[0,a^2-1,1],[b,0,1])];

determinant(A);

determinant(B);

determinant(A.B);

solve(determinant(A.B)=0,a);

6. zadatak

A: matrix([0,1,-1,4],[2,1,0,1],[3,2,2,5],[-2,-4,-1,1]);

invert(A);

doallmxops: false$
invert(A);

doallmxops: true$

adjunkta i determinanta

adjoint(A);

determinant(A);

## Rang matrice

A: matrix([2,6,-4,1,2],[4,-12,8,0,-4],[-3,9,2,-2,3]);

rank(A);

B: matrix([1,-2,0,4,3,0],[-2,0,5,2,6,1],[0,1,1,3,-2,-1],[-1,-2,5,6,9,1],[1,0,2,10,-1,-2]);

rank(B);

C: matrix([3,2,0,1],[1,-1,1,1],[4,2,-1,1],[0,0,2,1]);

rank(C);