# Pokazatelji isplativosti ulaganja

load("FINMAT.mac");

load("draw");

1. zadatak
Investitoru su prezentirana dva projekta A i B s dobicima krajem godina danima u tablici. Pomoću NPV metode odaberite isplativiji projekt ako znamo da je cijena kapitala 8%.

projekt |         0      |        1      |        2       |        3      |        4
----------+-------------+-------------+-------------+-------------+-------------
    A      |  -600 000  |  180 000  |  160 000  |  170 000  |  210 000
    B      |  -600 000  |  100 000  |  140 000  |  215 000  |  300 000

Odredite interne stope rentabilnosti projekata A i B.

projektA:[-600000,180000,160000,170000,210000]$
projektB:[-600000,100000,140000,215000,300000]$

NPV projekta A

NPV(8,projektA);

NPV projekta B

NPV(8,projektB);

NPV projekata A i B kao funkcija cijene kapitala

r:1+p/100$
NPVA:-600000+180000/r+160000/r^2+170000/r^3+210000/r^4;
NPVB:-600000+100000/r+140000/r^2+215000/r^3+300000/r^4;

wxplot2d([NPVA,NPVB], [p,0,18], [y,-120000,200000],grid2d,[ylabel,"NPV"],[legend,"NPV(A)","NPV(B)"])$

interne stope rentabilnosti

IRR(projektA);

IRR(projektA),FIN_dec:5;

IRR(projektB);

IRR(projektB),FIN_dec:5;

2. zadatak
Investitoru je ponuđen projekt u koji treba uložiti 1800 kn odmah i 10 500 kn za dvije godine. Očekivani dobici na kraju prve tri godine su dani u tablici.

+----------------------+-------------+-------------+-----------+
|      godina            |       1.      |       2.      |      3.      |
+----------------------+-------------+-------------+-----------+
| očekivani dobici   |  6500 kn  |  3750 kn  |  2500 kn |
+----------------------+-------------+-------------+-----------+

a) Radi li se o isplativom projektu ako je cijena kapitala 8%?
b) Radi li se o isplativom projektu ako je cijena kapitala 12%?
c) Odredite internu stopu rentabilnosti projekta.

projekt:[-1800,6050,3750-10500,2500];

a) dio: projekt nije isplativ 

NPV(8,projekt),FIN_dec:4;

b) dio: projekt je isplativ

NPV(12,projekt);

c) dio: postoji više internih stopa rentabilnosti

IRR(projekt),FIN_dec:5;

NPV projekta kao funkcija cijene kapitala

r:1+p/100$
NPVprojekt:-1800+6050/r-6750/r^2+2500/r^3;

wxplot2d(NPVprojekt, [p,0,28], [y,-1.2,1.2],grid2d,[ylabel,"NPV"])$

3. zadatak
U projekt treba uložiti 9 000 eura. Očekivani dobici na kraju prve tri godine su dani u tablici.

+----------------------+-------------+-------------+-----------+
|      godina            |       1.      |       2.      |      3.      |
+----------------------+-------------+-------------+-----------+
| očekivani dobici   |   3000 €   |   3500 €   |  4000 €  |
+----------------------+-------------+-------------+-----------+

a) Odredite NPV projekta ako je cijena kapitala 4.5445%.
b) Odredite NPV projekta ako je cijena kapitala 7.7285%.
c) Odredite internu stopu rentabilnosti projekta.
d) Ako je cijena kapitala 5%, do kojeg uloženog iznosa je investitoru projekt isplativ?

projekt:[-9000,3000,3500,4000]$
p1:4.5445$
p2:7.7285$

a) dio

NPV(p1,projekt),FIN_dec:5;

b) dio

NPV(p2,projekt),FIN_dec:5;

c) dio

IRR(projekt),FIN_dec:8;

d) dio

izraz:F0+3000/1.05+3500/1.05^2+4000/1.05^3;

rj:solve(izraz=0,F0),numer;

dec(rhs(rj[1]),2);

NPV projekta kao funkcija cijene kapitala

r:1+p/100$
NPVprojekt:-9000+3000/r+3500/r^2+4000/r^3;

wxplot2d(NPVprojekt, [p,0,30], [y,-3000,2000],grid2d,[ylabel,"NPV"],[xtics,2,2],[ytics,-3000,500])$

NPV projekta kao funkcija ulaganja uz p=5%

fun:-F0+3000/1.05+3500/1.05^2+4000/1.05^3;

wxplot2d(fun, [F0,0,15000], [y,-6000,10000],grid2d,[ylabel,"NPV"],[color,red])$

NPV kao funkcija ulaganja i cijene kapitala

ploha:-x+3000/(1+y/100)+3500/(1+y/100)^2+4000/(1+y/100)^3;

plava:subst(9000,x,ploha);

crvena:subst(5,y,ploha);

crna:[3000/(1+x/100)+3500/(1+x/100)^2+4000/(1+x/100)^3, x, 0];

wxdraw3d(xu_grid=15, yv_grid=15, surface_hide=true,color=skyblue,
               xlabel="F_0", ylabel="p", zlabel="NPV  ", explicit(ploha,x,0,15000,y,0,30),
              color=blue, line_width=2,  parametric(9000,y,plava+9,y,0,30), label(["F_0=9000",8000,0,80]),
              color=red, parametric(x,5,crvena+3,x,0,15000), label(["p=5",14000,8,-8000]),
              color=black, parametric(crna[1],crna[2],crna[3]+4,x,0,30), label(["NPV=0",7000,30,1500]),
              user_preamble= "set xyplane at -10000") ,wxplot_size=[900,600]$

4. zadatak
Koliki prihod je na kraju druge godine ostvarila investicija visine 200 000 kn uz cijenu kapitala 7% ako je NPV
jednak 14 559.82 kn, a prihodi na kraju prve i treće godine su redom 50 000 kn i 120 000 kn?

r:1.07$
F0:-200000$
F1:50000$
F3:120000$
Y:14559.82$

rj:solve(Y=F0+F1/r+F2/r^2+F3/r^3,F2),numer;

dec(rhs(rj[1]),2);

5. zadatak
NPV i IRR metodom ocijenite je li isplativ projekt u koji treba uložiti 200 000 kn, a koji na kraju prve godine donosi 50 000 kn, a na kraju druge godine 180 000 kn dobiti. Investitor sredstva za ulaganje u projekt posuđuje po godišnjoj kamatnoj stopi od 7%.

q:[-200000,50000,180000]$

Projekt je isplativ jer je NPV > 0.

NPV(7,q);

Projekt je isplativ jer je IRR > 7.

IRR(q),FIN_dec:5;

NPV projekta kao funkcija cijene kapitala

r:1+p/100$
NPVprojekt:q[1]+q[2]/r+q[3]/r^2;

wxplot2d(NPVprojekt, [p,0,30],grid2d,[ylabel,"NPV"],[xtics,4,4])$

6. zadatak
Banka mora odlučiti između dviju investicija u iznosu od 200 000 € čiji novčani 
tokovi su procijenjeni u sljedećoj tablici.

 godina |         0      |       1       |       2       |        3      |        4      |       5            
----------+-------------+-------------+------------+-------------+-------------+-------------
    A      |  -200 000  |   80 000  |   60 000   |   70 000   |  100 000  |  100 000
    B      |  -200 000  |   30 000  |   85 000   |   95 000   |   90 000   |   85 000

a) Odredite NPV oba projekta uz cijenu kapitala 7%.
b) Odredite IRR oba projekta.

pA:[-200000,80000,60000,70000,100000,100000]$
pB:[-200000,30000,85000,95000,90000,85000]$

a) dio: isplativiji je projekt A jer ima veći pozitivni NPV.

NPV(7,pA);

NPV(7,pB);

b) dio

IRR(pA),FIN_dec:5;

IRR(pB),FIN_dec:5;

NPV projekata A i B kao funkcija cijene kapitala

r:1+p/100$
NPVA:pA[1]+pA[2]/r+pA[3]/r^2+pA[4]/r^3+pA[5]/r^4+pA[6]/r^5;
NPVB:pB[1]+pB[2]/r+pB[3]/r^2+pB[4]/r^3+pB[5]/r^4+pB[6]/r^5;

wxplot2d([NPVA,NPVB], [p,0,55],grid2d,[ylabel,"NPV"],[legend,"NPV(A)","NPV(B)"],[xtics,5,5])$