verzija: SageMath 9.4
SAGE kao i python počinje numeraciju s brojem nula u listama i matricama. Stoga, prema našoj definiciji element na poziciji $(1,3)$ je u SAGE-u zapravo na poziciji $(0,2)$. Općenito, element na poziciji $(i,j)$ je u SAGE-u na poziciji $(i-1,j-1)$. To treba imati na umu kada radimo s matricama u SAGE-u, što već možete vidjeti u sljedećem zadatku.
Napišite matricu $A=\big[a_{ij}\big]$ tipa $(3,4)$ ako je $a_{ij}=\begin{cases}\cos{\frac{i\pi}{2}},&\text{ za }i>j\\ \log_2{(i+j)},&\text{ za }i\leq j\end{cases}.$
1. način. Možemo najprije definirati python listu, a zatim iz nje dobiti matricu pomoću naredbe matrix. Python lista nije matrica i ne podržava metode na matricama (poput računanja determinanti, binarne operacije s matricama i slično). Stoga je uvijek važno upotrijebiti ključnu riječ matrix kako bismo zaista u SAGE-u kreirali matricu koja će podržavati sve standardne operacije s matricama.
a je python lista
a=[[cos((i*pi)/2) if i>j else log(i+j,2) for j in range(1,5)] for i in range(1,4)]
a
A je matrica
A=matrix(a)
A
show(A)
A je matrica nad simboličkim prstenom (zbog logaritamske funkcije)
A.parent()
A.base_ring()
element na poziciji $(1,1)$
a[0][0]
A[0,0]
element na poziciji $(2,3)$
a[1][2]
A[1,2]
dimenzije matrice $A$
A.nrows(),A.ncols()
2. način. Možemo odmah kreirati matricu bez da prethodno definiramo python listu. Imajte ovdje na umu spomenutu važnu napomenu. Na prvi pogled malo drukčije izgleda definicija matrice A1, ali to je zbog toga što naša pozicija $(i,j)$ odgovara u SAGE-u poziciji $(i-1,j-1)$. Kada smo gore matricu definirali preko python liste, tu činjenicu smo imali na umu u naredbi range.
A1=matrix(3,4,lambda i,j: cos((i+1)*pi/2) if i>j else log(i+j+2,2))
show(A1)
želite li saznati više detalja o naredbi matrix
Zadane su matrice
$$A=\begin{bmatrix}1&2\\ 0&-3\\ 5&4 \end{bmatrix} \quad\text{i}\quad B=\begin{bmatrix}1&0&-2&5\\ 8&4&-1&3\end{bmatrix}.$$Odredite $A^T$, $AB$ i $BA$.
A=matrix([[1,2],[0,-3],[5,4]])
B=matrix([[1,0,-2,5],[8,4,-1,3]])
$A^T$
A.transpose()
$AB$
A*B
SAGE nas upozorava da $BA$ nije definirano
B*A
Odredite matricu $3AB-7BA$ ako je
$$A=\begin{bmatrix}3&1&-4\\ -4&6&-2\\ 5&8&5\end{bmatrix} \quad\text{i}\quad B=\begin{bmatrix}3&7&-4\\ 2&1&0\\ -5&3&2\end{bmatrix}.$$A=matrix([[3,1,-4],[-4,6,-2],[5,8,5]])
B=matrix([[3,7,-4],[2,1,0],[-5,3,2]])
$AB$
A*B
$3AB$
3*A*B
$BA$
B*A
$7BA$
7*B*A
$3AB-7BA$
3*A*B-7*B*A
Zadana je matrica $A=\begin{bmatrix}3&-2\\ -1&5\end{bmatrix}$ i polinom $f(x)=x^3+2x^2+3$. Odredite $f(A)$.
A=matrix([[3,-2],[-1,5]])
$A$ je matrica nad prstenom $\mathbb{Z}$
A.base_ring()
jedinična matrica reda 2
identity_matrix(2)
jedinična matrica reda 5
identity_matrix(5)
$A^2$
A*A
A^2
$A^3$
A^3
$f(A)=A^3+2A^2+3I$
A^3+2*A^2+3*identity_matrix(2)
Izračunajte $\begin{bmatrix}2&-2&0\\ 1&-2&1\end{bmatrix}\begin{bmatrix}2\\ 1\\ 3\end{bmatrix}$.
matrix([[2,-2,0],[1,-2,1]])*matrix([[2],[1],[3]])
Izračunajte $AB$ ako je $A=\begin{bmatrix}2&3\\ 1&5\end{bmatrix}$, $B=\dfrac{9}{5}\begin{bmatrix}1&0&4\\ 3&6&8\end{bmatrix}$.
A=matrix([[2,3],[1,5]])
B=9/5*matrix([[1,0,4],[3,6,8]])
A*B
show(A*B)
Odredite $A^n$ za proizvoljni $n\in\mathbb{N}$ ako je $A=\begin{bmatrix}1&3\\ 0&1\end{bmatrix}$.
A=matrix([[1,3],[0,1]])
for n in range(1,21):
print("A^%d="%n)
print(A^n)
print("\n")
Gledajući prvih 20 potencija matrice $A$ razumno je da donesemo hipotezu $A^n=\left[\begin{smallmatrix}1&3n\\ 0&1\end{smallmatrix}\right]$. Naravno, mi tu hipotezu moramo dokazati matematičkom indukcijom. Ovdje smo zapravo proveli nepotpunu indukciju koju matematika ne priznaje kao dokaz.
Odredite sve matrice koje komutiraju s matricom $A$ s obzirom na množenje ako je $A=\begin{bmatrix}1&1\\ 0&1\end{bmatrix}$.
var('a b c d')
A=matrix([[1,1],[0,1]])
X=matrix([[a,b],[c,d]])
A*X-X*A
solve([c==0,-a+d==0,-c==0],a,b,c,d)
Možemo definirati svoju funkciju koja će direktno raditi s matricama
def solve_mat(lijevo,desno,varijable):
jednadzbe=[]
for i in range(lijevo.nrows()):
for j in range(lijevo.ncols()):
jednadzbe.append(lijevo[i,j]==desno[i,j])
rj=solve(jednadzbe,*varijable)
return rj
solve_mat(A*X,X*A,(a,b,c,d))
Izračunajte determinante:
$$\begin{vmatrix}2&5\\ 1&-3\end{vmatrix},\quad \begin{vmatrix}x-a&-a\\ a&x+a\end{vmatrix},\quad \begin{vmatrix}\sin{\alpha}&\cos{\alpha}\\ \sin{\beta}&\cos{\beta}\end{vmatrix}.$$det(matrix([[2,5],[1,-3]]))
matrix([[2,5],[1,-3]]).det()
expand(det(matrix([[x-a,-a],[a,x+a]])))
matrix([[x-a,-a],[a,x+a]]).det().expand()
det(matrix([[sin(a),cos(a)],[sin(b),cos(b)]]))
Izračunajte determinantu matrice $A=\begin{bmatrix}9&4&-5\\ 8&7&-2\\ 2&-1&8\end{bmatrix}$.
A=matrix(3,3,[9,4,-5,8,7,-2,2,-1,8])
A
det(A)
A.det()
Izračunajte determinantu matrice $A=\begin{bmatrix}2&-5&1&2\\ -3&7&-1&4\\ 5&-9&2&7\\ 4&-6&1&2\end{bmatrix}$.
A=matrix(4,4,[2,-5,1,2,-3,7,-1,4,5,-9,2,7,4,-6,1,2])
A
det(A)
A.det()
Zadana je matrica $A=\begin{bmatrix}4+x&2&2\\ 7&x-1&2\\ x+1&5&5\end{bmatrix}$.
A=matrix(3,3,[4+x,2,2,7,x-1,2,x+1,5,5])
a) dio
expand(det(A))
solve(det(A)==0,x)
b) dio
det(A.transpose())+5*det(A^3)-2*det(1/2*A)
expand(det(A.transpose())+5*det(A^3)-2*det(1/2*A)).show()
expand(det(A.transpose())+5*det(A^3)-2*det(1/2*A)).subs(x==-1)
ili da najprije $x=-1$ uvrstimo u matricu $A$
A.subs(x==-1)
det(A.subs(x==-1))
expand(det(A.subs(x==-1).transpose())+5*det(A.subs(x==-1)^3)-2*det(1/2*A.subs(x==-1)))
Izračunajte determinantu $\begin{vmatrix}3&a&3&a\\ 6&3&6&3\\ 7&7&6&6\\ a&5&a&5\end{vmatrix}$.
det(matrix(4,4,[3,a,3,a,6,3,6,3,7,7,6,6,a,5,a,5]))
matrix(4,4,[3,a,3,a,6,3,6,3,7,7,6,6,a,5,a,5]).det()
Izračunajte determinantu $\begin{vmatrix}a&a&a&a&a\\ -2&a&a&a&a\\ 2&0&a&a&a\\ -4&0&0&a&a\\ 4&0&0&0&a\end{vmatrix}$.
det(matrix(5,5,[a,a,a,a,a,-2,a,a,a,a,2,0,a,a,a,-4,0,0,a,a,4,0,0,0,a]))
det(matrix(5,5,[a,a,a,a,a,-2,a,a,a,a,2,0,a,a,a,-4,0,0,a,a,4,0,0,0,a])).show()
matrix(5,5,[a,a,a,a,a,-2,a,a,a,a,2,0,a,a,a,-4,0,0,a,a,4,0,0,0,a]).det().show()
Riješite jednadžbu $\begin{vmatrix}x-3&3&3&3\\ 3&2x+3&3&3\\ 3&3&x-3&3\\ 3&3&3&2x+3\end{vmatrix}=0.$
det(matrix(4,4,[x-3,3,3,3,3,2*x+3,3,3,3,3,x-3,3,3,3,3,2*x+3])).show()
det(matrix(4,4,[x-3,3,3,3,3,2*x+3,3,3,3,3,x-3,3,3,3,3,2*x+3])).factor().show()
solve(det(matrix(4,4,[x-3,3,3,3,3,2*x+3,3,3,3,3,x-3,3,3,3,3,2*x+3]))==0,x)
show(solve(det(matrix(4,4,[x-3,3,3,3,3,2*x+3,3,3,3,3,x-3,3,3,3,3,2*x+3]))==0,x))
Odredite inverzne matrice matrica $A=\begin{bmatrix}2&1\\ -5&4\end{bmatrix}$ i $B=\dfrac{2}{3}\begin{bmatrix}3&5\\ 1&-3\end{bmatrix}$.
A=matrix([[2,1],[-5,4]])
B=2/3*matrix([[3,5],[1,-3]])
A^-1
show(A^-1)
A.inverse()
~A
B^-1
show(B^-1)
B.inverse()
~B
Odredite inverznu matricu matrice $E=\begin{bmatrix}-3&4&-5\\ 4&-3&2\\ 1&-3&4\end{bmatrix}$.
E=matrix(3,3,[-3,4,-5,4,-3,2,1,-3,4])
E^-1
show(E^-1)
E.inverse()
~E
adjunkta matrice $E$
E.adjugate()
Za koje vrijednosti parametara $a,b\in\mathbb{R}$ je matrica $AB$ regularna ako je
$$A=\begin{bmatrix}a&1&-1\\ -1&1&1\\ -2&0&0\end{bmatrix},\quad B=\begin{bmatrix}1&0&0\\ 0&a^2-1&1\\ b&0&1\end{bmatrix}.$$A=matrix(3,3,[a,1,-1,-1,1,1,-2,0,0])
B=matrix(3,3,[1,0,0,0,a^2-1,1,b,0,1])
det(A*B)
solve(det(A*B)==0,a)
Dakle, $\det{(AB)}=0$ jedino za $a=1$ i $a=-1$. Stoga je $AB$ regularna matrica za svaki $b\in\mathbb{R}$ i za sve $a\in\mathbb{R}\setminus\{-1,1\}$.
Odredite matricu $X$ tako da vrijedi jednakost $AX=B$ ako je $A=\begin{bmatrix}1&2\\ -2&0\end{bmatrix}$, $B=\begin{bmatrix}2&0&-1\\ 0&-2&1\end{bmatrix}$.
A=matrix(2,2,[1,2,-2,0])
B=matrix(2,3,[2,0,-1,0,-2,1])
1. način
A^-1*B
show(A^-1*B)
2. način
A\B
show(A\B)
3. način
A.solve_right(B)
show(A.solve_right(B))
4. način
var('x1,x2,x3,x4,x5,x6')
X=matrix(2,3,[x1,x2,x3,x4,x5,x6])
solve_mat(A*X,B,(x1,x2,x3,x4,x5,x6))
Riješite matričnu jednadžbu $XA=B$ ako je $A=\begin{bmatrix}1&2\\ -2&0\end{bmatrix}$, $B=\begin{bmatrix}2&0\\ -1&0\\ -2&1\end{bmatrix}$.
A=matrix(2,2,[1,2,-2,0])
B=matrix(3,2,[2,0,-1,0,-2,1])
1. način
B*A^-1
2. način
A.solve_left(B)
3. način
X=matrix(3,2,[x1,x2,x3,x4,x5,x6])
solve_mat(X*A,B,(x1,x2,x3,x4,x5,x6))
Riješite matričnu jednadžbu $AX=B$ ako je $A=\begin{bmatrix}1&1\\ 1&1\end{bmatrix}$, $B=\begin{bmatrix}1&2\\ 3&0\end{bmatrix}$.
A=matrix(2,2,[1,1,1,1])
B=matrix(2,2,[1,2,3,0])
det(A)
A\B
A.solve_right(B)
X=matrix(2,2,[x1,x2,x3,x4])
solve_mat(A*X,B,(x1,x2,x3,x4))
Zaključujemo da zadana matrična jednadžba nema rješenja.
Riješite matričnu jednadžbu $AX=B$ ako je $A=\begin{bmatrix}1&1\\ 1&1\end{bmatrix}$, $B=\begin{bmatrix}2&5\\ 2&5\end{bmatrix}$.
A=matrix(2,2,[1,1,1,1])
B=matrix(2,2,[2,5,2,5])
det(A)
A\B
A.solve_right(B)
želimo li dobiti sva rješenja
X=matrix(2,2,[x1,x2,x3,x4])
solve_mat(A*X,B,(x1,x2,x3,x4))
ako želimo da varijable x1 i x2 budu parametri
solve_mat(A*X,B,(x3,x4,x1,x2))
Odredite matricu $X$ tako da vrijedi $XB+A=AXB$ ako je $A=\dfrac{1}{3}\begin{bmatrix}4&-5\\ 2&1\end{bmatrix}$ i $A+B=I$.
A=1/3*matrix(2,2,[4,-5,2,1])
B=identity_matrix(2)-A
X=matrix(2,2,[a,b,c,d])
solve_mat(X*B+A,A*X*B,(a,b,c,d))